media-sound/elisa/elisa-20.04.1.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 ECM_HANDBOOK="optional"
   7 ECM_TEST="forceoptional"
   8 KDE_RELEASE_SERVICE="true"
   9 KFMIN=5.70.0
  10 QTMIN=5.12.3
  11 inherit ecm kde.org
  12
  13 DESCRIPTION="Simple music player by KDE"
  14 HOMEPAGE="https://community.kde.org/Elisa"
  15
  16 LICENSE="LGPL-3+"
  17 SLOT="5"
  18 KEYWORDS="~amd64 ~arm64 ~x86"
  19 IUSE="mpris semantic-desktop vlc"
  20
  21 BDEPEND="sys-devel/gettext"
  22 DEPEND="
  23         >=dev-qt/qtdeclarative-${QTMIN}:5
  24         >=dev-qt/qtgui-${QTMIN}:5
  25         >=dev-qt/qtmultimedia-${QTMIN}:5
  26         >=dev-qt/qtsql-${QTMIN}:5
  27         >=dev-qt/qtwidgets-${QTMIN}:5
  28         >=kde-frameworks/kconfig-${KFMIN}:5
  29         >=kde-frameworks/kconfigwidgets-${KFMIN}:5
  30         >=kde-frameworks/kcoreaddons-${KFMIN}:5
  31         >=kde-frameworks/kcrash-${KFMIN}:5
  32         >=kde-frameworks/kdeclarative-${KFMIN}:5
  33         >=kde-frameworks/kfilemetadata-${KFMIN}:5[taglib]
  34         >=kde-frameworks/ki18n-${KFMIN}:5
  35         >=kde-frameworks/kio-${KFMIN}:5
  36         >=kde-frameworks/kirigami-${KFMIN}:5
  37         >=kde-frameworks/kitemviews-${KFMIN}:5
  38         >=kde-frameworks/kxmlgui-${KFMIN}:5
  39         mpris? (
  40                 >=dev-qt/qtdbus-${QTMIN}:5
  41                 >=kde-frameworks/kdbusaddons-${KFMIN}:5
  42         )
  43         semantic-desktop? ( >=kde-frameworks/baloo-${KFMIN}:5 )
  44         vlc? ( media-video/vlc:= )
  45         !vlc? ( >=dev-qt/qtmultimedia-${QTMIN}:5[gstreamer] )
  46 "
  47 RDEPEND="${DEPEND}
  48         >=dev-qt/qtgraphicaleffects-${QTMIN}:5
  49         >=dev-qt/qtquickcontrols2-${QTMIN}:5
  50 "
  51
  52 RESTRICT+=" test"
  53
  54 src_configure() {
  55         local mycmakeargs=(
  56                 $(cmake_use_find_package mpris KF5DBusAddons)
  57                 $(cmake_use_find_package semantic-desktop KF5Baloo)
  58                 $(cmake_use_find_package vlc LIBVLC)
  59         )
  60
  61         ecm_src_configure
  62 }