media-sound/ecasound/ecasound-2.6.0-r1.ebuild

   1 # Copyright 1999-2018 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 PYTHON_COMPAT=( python2_7 )
   6
   7 inherit eutils python-single-r1
   8
   9 DESCRIPTION="a package for multitrack audio processing"
  10 HOMEPAGE="https://ecasound.seul.org/ecasound/"
  11 SRC_URI="https://${PN}.seul.org/download/${P}.tar.gz"
  12
  13 LICENSE="GPL-2"
  14 SLOT="1"
  15 KEYWORDS="amd64 ~ppc x86"
  16 IUSE="alsa audiofile debug doc jack libsamplerate mikmod ncurses vorbis oss python ruby sndfile"
  17
  18 RDEPEND="python? ( ${PYTHON_DEPS} )
  19         jack? ( media-sound/jack-audio-connection-kit )
  20         media-libs/ladspa-sdk
  21         audiofile? ( media-libs/audiofile )
  22         alsa? ( media-libs/alsa-lib )
  23         vorbis? ( media-libs/libvorbis )
  24         libsamplerate? ( media-libs/libsamplerate )
  25         mikmod? ( media-libs/libmikmod:0 )
  26         ruby? ( dev-lang/ruby )
  27         python? ( dev-lang/python )
  28         ncurses? ( sys-libs/ncurses )
  29         sndfile? ( media-libs/libsndfile )
  30         sys-libs/readline"
  31 DEPEND="${RDEPEND}"
  32
  33 REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
  34
  35 pkg_setup() {
  36         use python && python-single-r1_pkg_setup
  37 }
  38
  39 src_configure() {
  40         local pyconf=()
  41
  42         if use python ; then
  43                 pyconf=( "--with-python-modules=${EPREFIX}/usr/$(get_libdir)/${EPYTHON}" )
  44         fi
  45
  46         econf \
  47                 $(use_enable alsa) \
  48                 --disable-arts \
  49                 $(use_enable audiofile) \
  50                 $(use_enable debug) \
  51                 $(use_enable jack) \
  52                 $(use_enable libsamplerate) \
  53                 $(use_enable ncurses) \
  54                 $(use_enable oss) \
  55                 $(use_enable python pyecasound c) \
  56                 $(use_enable ruby rubyecasound) \
  57                 $(use_enable sndfile) \
  58                 --enable-shared \
  59                 --with-largefile \
  60                 --enable-sys-readline \
  61                 "${pyconf[@]}"
  62 }
  63
  64 src_install() {
  65         emake DESTDIR="${D}" install
  66         use python && python_optimize
  67         dodoc BUGS NEWS README TODO
  68         use doc && dodoc Documentation/*.html
  69 }