media-sound/cadence/cadence-0.9.0-r4.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 PYTHON_COMPAT=( python3_{6,7} )
   7 inherit python-single-r1 xdg desktop
   8
   9 DESCRIPTION="Collection of tools useful for audio production"
  10 HOMEPAGE="http://kxstudio.linuxaudio.org/Applications:Cadence"
  11 SRC_URI="https://github.com/falkTX/Cadence/archive/v${PV}.tar.gz -> ${P}.tar.gz"
  12 KEYWORDS="amd64"
  13 LICENSE="GPL-2"
  14 SLOT="0"
  15
  16 IUSE="a2jmidid -pulseaudio opengl"
  17
  18 REQUIRED_USE="${PYTHON_REQUIRED_USE}"
  19
  20 # for jack project rendering also needs media-sound/jack_capture which is not in the tree yet
  21 CDEPEND="
  22         ${PYTHON_DEPS}
  23         $(python_gen_cond_dep '
  24                 dev-python/dbus-python[${PYTHON_MULTI_USEDEP}]
  25                 dev-python/PyQt5[dbus,gui,opengl?,svg,widgets,${PYTHON_MULTI_USEDEP}]
  26         ')
  27         media-sound/jack2[dbus]
  28         media-sound/jack_capture
  29         a2jmidid? ( media-sound/a2jmidid[dbus] )
  30         pulseaudio? ( media-sound/pulseaudio[jack] )
  31 "
  32 RDEPEND="${CDEPEND}"
  33 DEPEND="${CDEPEND}"
  34
  35 S="${WORKDIR}/Cadence-${PV}"
  36
  37 PATCHES=( "${FILESDIR}"/${PN}-add-skip-stripping.patch )
  38
  39 src_prepare() {
  40         sed -i -e "s/python3/${EPYTHON}/" \
  41                 data/cadence \
  42                 data/cadence-aloop-daemon \
  43                 data/cadence-jacksettings \
  44                 data/cadence-logs \
  45                 data/cadence-render \
  46                 data/cadence-session-start \
  47                 data/catarina \
  48                 data/catia \
  49                 data/claudia \
  50                 data/claudia-launcher || die "sed failed"
  51
  52         default
  53 }
  54
  55 src_compile() {
  56         myemakeargs=(PREFIX="/usr"
  57                 SKIP_STRIPPING=true
  58         )
  59
  60         emake "${myemakeargs[@]}"
  61 }
  62
  63 src_install() {
  64         emake PREFIX="/usr" DESTDIR="${D}" install
  65
  66         # Clean up stuff that shouldn't be installed
  67         rm -rf "${D}"/etc/X11/xinit/xinitrc.d/61cadence-session-inject
  68         rm -rf "${D}"/etc/xdg/autostart/cadence-session-start.desktop
  69         rm -rf "${D}"/usr/share/applications/*.desktop
  70
  71         if use !pulseaudio; then
  72                 rm -rf "${D}"/usr/bin/cadence-pulse2{jack,loopback}
  73                 rm -rf "${D}"/usr/share/cadence/pulse2{jack,loopback}
  74         fi
  75
  76         # Replace desktop entries with QA issues with these
  77         make_desktop_entry cadence Cadence cadence "AudioVideo;AudioVideoEditing;Qt"
  78         make_desktop_entry catia Catia catia "AudioVideo;AudioVideoEditing;Qt"
  79         make_desktop_entry catarina Catarina catarina "AudioVideo;AudioVideoEditing;Qt"
  80 }