media-sound/aqualung/aqualung-1.0-r2.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit eutils
   7
   8 MY_PV=${PV/_/-}
   9
  10 DESCRIPTION="Music player for a wide range of formats designed for gapless playback"
  11 HOMEPAGE="http://aqualung.jeremyevans.net/ https://github.com/jeremyevans/aqualung"
  12 SRC_URI="mirror://sourceforge/aqualung/${PN}-${MY_PV}.tar.gz"
  13
  14 LICENSE="GPL-2"
  15 SLOT="0"
  16 KEYWORDS="amd64 x86"
  17 IUSE="alsa cdda cddb debug flac ffmpeg ifp jack ladspa lame libav libsamplerate
  18         lua mac modplug mp3 musepack oss podcast pulseaudio sndfile speex systray
  19         vorbis wavpack"
  20
  21 RDEPEND="
  22         app-arch/bzip2
  23         dev-libs/libxml2
  24         sys-libs/zlib
  25         x11-libs/gtk+:2
  26         alsa? ( media-libs/alsa-lib )
  27         cdda? ( dev-libs/libcdio-paranoia )
  28         cddb? ( media-libs/libcddb )
  29         ffmpeg? (
  30                 libav? ( media-video/libav:0= )
  31                 !libav? ( media-video/ffmpeg:0= )
  32         )
  33         flac? ( media-libs/flac )
  34         ifp? ( media-libs/libifp )
  35         jack? ( media-sound/jack-audio-connection-kit )
  36         ladspa? ( media-libs/liblrdf )
  37         lame? ( media-sound/lame )
  38         libsamplerate? ( media-libs/libsamplerate )
  39         lua? ( dev-lang/lua:0= )
  40         mac? ( >=media-sound/mac-4.11.4.5.7 )
  41         modplug? ( media-libs/libmodplug )
  42         mp3? ( media-libs/libmad )
  43         musepack? ( >=media-sound/musepack-tools-444 )
  44         pulseaudio? ( media-sound/pulseaudio )
  45         sndfile? ( media-libs/libsndfile )
  46         speex? ( media-libs/speex media-libs/liboggz media-libs/libogg )
  47         vorbis? ( media-libs/libvorbis media-libs/libogg )
  48         wavpack? ( media-sound/wavpack )
  49 "
  50 DEPEND="${RDEPEND}
  51         sys-devel/gettext
  52         virtual/pkgconfig
  53 "
  54
  55 S=${WORKDIR}/${PN}-${MY_PV}
  56
  57 PATCHES=(
  58         "${FILESDIR}/${P}-ffmpeg3.patch"
  59 )
  60
  61 src_configure() {
  62         econf \
  63                 --disable-rpath \
  64                 --enable-loop \
  65                 --enable-nls \
  66                 --enable-transcoding \
  67                 $(use_enable debug) \
  68                 $(use_enable podcast) \
  69                 $(use_enable systray) \
  70                 $(use_enable jack jack-mgmt) \
  71                 $(use_with alsa) \
  72                 $(use_with cdda) \
  73                 $(use_with cddb) \
  74                 $(use_with ffmpeg lavc) \
  75                 $(use_with flac) \
  76                 $(use_with ifp) \
  77                 $(use_with jack) \
  78                 $(use_with ladspa) \
  79                 $(use_with lame) \
  80                 $(use_with libsamplerate src) \
  81                 $(use_with lua) \
  82                 $(use_with mac) \
  83                 $(use_with modplug mod) \
  84                 $(use_with mp3 mpeg) \
  85                 $(use_with musepack mpc) \
  86                 $(use_with oss) \
  87                 $(use_with pulseaudio pulse) \
  88                 $(use_with sndfile) \
  89                 $(use_with speex) \
  90                 $(use_with vorbis vorbis) \
  91                 $(use_with vorbis vorbisenc) \
  92                 $(use_with wavpack)
  93 }
  94
  95 src_install() {
  96         default
  97
  98         newicon src/img/icon_64.png aqualung.png
  99         make_desktop_entry aqualung Aqualung
 100 }