media-sound/aqualung/aqualung-1.0-r2.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit eutils
   7
   8 MY_PV=${PV/_/-}
   9
  10 DESCRIPTION="Music player for a wide range of formats designed for gapless playback"
  11 HOMEPAGE="http://aqualung.jeremyevans.net/ https://github.com/jeremyevans/aqualung"
  12 SRC_URI="mirror://sourceforge/aqualung/${PN}-${MY_PV}.tar.gz"
  13
  14 LICENSE="GPL-2"
  15 SLOT="0"
  16 KEYWORDS="amd64 x86"
  17 IUSE="alsa cdda cddb debug flac ffmpeg ifp jack ladspa lame libsamplerate
  18         lua mac modplug mp3 musepack oss podcast pulseaudio sndfile speex systray
  19         vorbis wavpack"
  20
  21 RDEPEND="
  22         app-arch/bzip2
  23         dev-libs/libxml2
  24         sys-libs/zlib
  25         x11-libs/gtk+:2
  26         alsa? ( media-libs/alsa-lib )
  27         cdda? ( dev-libs/libcdio-paranoia )
  28         cddb? ( media-libs/libcddb )
  29         ffmpeg? ( media-video/ffmpeg:0= )
  30         flac? ( media-libs/flac )
  31         ifp? ( media-libs/libifp )
  32         jack? ( media-sound/jack-audio-connection-kit )
  33         ladspa? ( media-libs/liblrdf )
  34         lame? ( media-sound/lame )
  35         libsamplerate? ( media-libs/libsamplerate )
  36         lua? ( dev-lang/lua:0= )
  37         mac? ( >=media-sound/mac-4.11.4.5.7 )
  38         modplug? ( media-libs/libmodplug )
  39         mp3? ( media-libs/libmad )
  40         musepack? ( >=media-sound/musepack-tools-444 )
  41         pulseaudio? ( media-sound/pulseaudio )
  42         sndfile? ( media-libs/libsndfile )
  43         speex? ( media-libs/speex media-libs/liboggz media-libs/libogg )
  44         vorbis? ( media-libs/libvorbis media-libs/libogg )
  45         wavpack? ( media-sound/wavpack )
  46 "
  47 DEPEND="${RDEPEND}
  48         sys-devel/gettext
  49         virtual/pkgconfig
  50 "
  51
  52 S=${WORKDIR}/${PN}-${MY_PV}
  53
  54 PATCHES=(
  55         "${FILESDIR}/${P}-ffmpeg3.patch"
  56 )
  57
  58 src_configure() {
  59         econf \
  60                 --disable-rpath \
  61                 --enable-loop \
  62                 --enable-nls \
  63                 --enable-transcoding \
  64                 $(use_enable debug) \
  65                 $(use_enable podcast) \
  66                 $(use_enable systray) \
  67                 $(use_enable jack jack-mgmt) \
  68                 $(use_with alsa) \
  69                 $(use_with cdda) \
  70                 $(use_with cddb) \
  71                 $(use_with ffmpeg lavc) \
  72                 $(use_with flac) \
  73                 $(use_with ifp) \
  74                 $(use_with jack) \
  75                 $(use_with ladspa) \
  76                 $(use_with lame) \
  77                 $(use_with libsamplerate src) \
  78                 $(use_with lua) \
  79                 $(use_with mac) \
  80                 $(use_with modplug mod) \
  81                 $(use_with mp3 mpeg) \
  82                 $(use_with musepack mpc) \
  83                 $(use_with oss) \
  84                 $(use_with pulseaudio pulse) \
  85                 $(use_with sndfile) \
  86                 $(use_with speex) \
  87                 $(use_with vorbis vorbis) \
  88                 $(use_with vorbis vorbisenc) \
  89                 $(use_with wavpack)
  90 }
  91
  92 src_install() {
  93         default
  94
  95         newicon src/img/icon_64.png aqualung.png
  96         make_desktop_entry aqualung Aqualung
  97 }