media-sound/apulse/apulse-0.1.12-r4.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit multilib cmake-multilib
   7
   8 DESCRIPTION="PulseAudio emulation for ALSA"
   9 HOMEPAGE="https://github.com/i-rinat/apulse"
  10 SRC_URI="https://github.com/i-rinat/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
  11
  12 LICENSE="MIT LGPL-2.1"
  13 SLOT="0"
  14 KEYWORDS="amd64 x86"
  15
  16 IUSE="debug sdk test"
  17 RESTRICT="!test? ( test )"
  18
  19 DEPEND="dev-libs/glib:2[${MULTILIB_USEDEP}]
  20         media-libs/alsa-lib[${MULTILIB_USEDEP}]
  21         sdk? ( !media-sound/pulseaudio ) "
  22 RDEPEND="${DEPEND}
  23         !!media-plugins/alsa-plugins[pulseaudio]"
  24
  25 PATCHES=( "${FILESDIR}/sdk.patch" )
  26
  27 src_prepare() {
  28         cmake-utils_src_prepare
  29
  30         if ! use sdk; then
  31                 # Ensure all relevant libdirs are added, to support all ABIs
  32                 DIRS=
  33                 _add_dir() { DIRS="${EPREFIX}/usr/$(get_libdir)/apulse${DIRS:+:${DIRS}}"; }
  34                 multilib_foreach_abi _add_dir
  35                 sed -e "s#@@DIRS@@#${DIRS}#g" "${FILESDIR}"/apulse > "${T}"/apulse || die
  36         fi
  37 }
  38
  39 multilib_src_configure() {
  40         local mycmakeargs=(
  41                 "-DINSTALL_SDK=$(usex sdk)"
  42                 "-DLOG_TO_STDERR=$(usex debug)"
  43                 "-DWITH_TRACE=$(usex debug)"
  44         )
  45         cmake-utils_src_configure
  46 }
  47
  48 multilib_src_test() {
  49         emake check
  50 }
  51
  52 multilib_src_install_all() {
  53         # Do not use deprecated MULTILIB_CHOST_TOOLS
  54         if ! use sdk; then
  55                 unset BUILD_DIR
  56                 _install_wrapper() { newbin "${BUILD_DIR}/apulse" "${CHOST}-apulse"; }
  57                 multilib_foreach_abi _install_wrapper
  58                 dobin "${T}/apulse"
  59         fi
  60         einstalldocs
  61 }