media-sound/apetag/apetag-1.12-r2.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 PYTHON_COMPAT=( python2_7 )
   7
   8 inherit python-single-r1 toolchain-funcs
   9
  10 DESCRIPTION="Command-line ape 2.0 tagger"
  11 HOMEPAGE="http://muth.org/Robert/Apetag/"
  12 SRC_URI="http://muth.org/Robert/Apetag/${PN}.${PV}.tar.gz"
  13
  14 LICENSE="GPL-3"
  15 SLOT="0"
  16 KEYWORDS="amd64 ppc ppc64 x86"
  17 IUSE=""
  18 REQUIRED_USE="${PYTHON_REQUIRED_USE}"
  19
  20 RDEPEND="${PYTHON_DEPS}"
  21 DEPEND="${RDEPEND}"
  22
  23 S=${WORKDIR}/${PN^}
  24
  25 src_prepare() {
  26         default
  27         sed -i \
  28                 -e 's:CXXDEBUG:LDFLAGS:' \
  29                 Makefile || die
  30         python_fix_shebang *.py
  31 }
  32
  33 src_compile() {
  34         tc-export CXX
  35         emake \
  36                 CXXFLAGS="${CXXFLAGS} -Wall -pedantic" \
  37                 LDFLAGS="${LDFLAGS}"
  38 }
  39
  40 src_install() {
  41         dobin ${PN}
  42
  43         python_moduleinto /usr/lib/apetag
  44         python_domodule *.py
  45
  46         fperms +x /usr/lib/apetag/{rmid3tag,tagdir}.py
  47         dosym ../lib/apetag/rmid3tag.py /usr/bin/rmid3tag.py
  48         dosym ../lib/apetag/tagdir.py /usr/bin/tagdir.py
  49
  50         newdoc 00readme README
  51 }