media-plugins/vdr-skinelchi/vdr-skinelchi-0.3.0-r2.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit vdr-plugin-2
   7
   8 DESCRIPTION="VDR Skin Plugin: skinelchi"
   9 HOMEPAGE="http://firefly.vdr-developer.org/skinelchi"
  10 SRC_URI="http://firefly.vdr-developer.org/skinelchi/${P}.tar.bz2"
  11
  12 SLOT="0"
  13 LICENSE="GPL-2"
  14 KEYWORDS="~amd64 ~x86"
  15
  16 DEPEND="media-video/vdr"
  17
  18 src_prepare() {
  19         vdr-plugin-2_src_prepare
  20
  21         #bug #599148
  22         append-cxxflags -std=gnu++11
  23
  24         # disable imagemagick support, broken ...
  25         sed -i "${S}"/Makefile -e \
  26                 "s:SKINELCHI_HAVE_IMAGEMAGICK = 1:SKINELCHI_HAVE_IMAGEMAGICK = 0:" || die
  27
  28         sed -i "${S}"/DisplayChannel.c \
  29                 -e "s:/hqlogos::" \
  30                 -e "s:/logos::" || die
  31
  32         # wrong sed in vdr-plugin-2.eclass?
  33         sed -e "s:INCLUDES += -I\$(VDRINCDIR):INCLUDES += -I\$(VDRINCDIR)/include:" \
  34                 -i Makefile || die
  35
  36         # gcc-6 warnings
  37         sed -e "s:auto_ptr:unique_ptr:" -i services/epgsearch_services.h || die
  38
  39         # wrt bug 703994
  40         eapply "${FILESDIR}/${P}_min_max_from_stl.patch"
  41 }