media-plugins/vdr-skinelchi/vdr-skinelchi-0.3.0-r1.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit flag-o-matic vdr-plugin-2
   7
   8 DESCRIPTION="VDR Skin Plugin: skinelchi"
   9 HOMEPAGE="http://firefly.vdr-developer.org/skinelchi"
  10 SRC_URI="http://firefly.vdr-developer.org/skinelchi/${P}.tar.bz2"
  11
  12 SLOT="0"
  13 LICENSE="GPL-2"
  14 KEYWORDS="~amd64 ~x86"
  15 IUSE=""
  16
  17 DEPEND="media-video/vdr"
  18
  19 src_prepare() {
  20         vdr-plugin-2_src_prepare
  21
  22         #bug #599148
  23         append-cxxflags -std=gnu++11
  24
  25         # disable imagemagick support, broken ...
  26         sed -i "${S}"/Makefile -e \
  27                 "s:SKINELCHI_HAVE_IMAGEMAGICK = 1:SKINELCHI_HAVE_IMAGEMAGICK = 0:" || die
  28
  29         sed -i "${S}"/DisplayChannel.c \
  30                 -e "s:/hqlogos::" \
  31                 -e "s:/logos::" || die
  32
  33         # wrong sed in vdr-plugin-2.eclass?
  34         sed -e "s:INCLUDES += -I\$(VDRINCDIR):INCLUDES += -I\$(VDRINCDIR)/include:" \
  35                 -i Makefile || die
  36
  37         # gcc-6 warnings
  38         sed -e "s:auto_ptr:unique_ptr:" -i services/epgsearch_services.h || die
  39 }