media-plugins/vdr-osdteletext/vdr-osdteletext-0.9.7.ebuild

   1 # Copyright 2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit vdr-plugin-2
   7
   8 VERSION="2161" # every bump, new version
   9
  10 DESCRIPTION="VDR Plugin: Osd-Teletext displays the teletext on the OSD"
  11 HOMEPAGE="https://projects.vdr-developer.org/projects/plg-osdteletext"
  12 SRC_URI="https://projects.vdr-developer.org/attachments/download/${VERSION}/${P}.tgz"
  13
  14 LICENSE="GPL-2+ public-domain" #teletext2.ttf, not copyrightable
  15 SLOT="0"
  16 KEYWORDS="~amd64 ~x86"
  17
  18 DEPEND="media-video/vdr"
  19 RDEPEND="${DEPEND}"
  20
  21 VDR_RCADDON_FILE="${FILESDIR}/rc-addon-v3.sh"
  22 VDR_CONFD_FILE="${FILESDIR}/confd-v2"
  23
  24 QA_FLAGS_IGNORED="
  25         usr/lib/vdr/plugins/libvdr-.*
  26         usr/lib64/vdr/plugins/libvdr-.*"
  27
  28 src_install() {
  29         vdr-plugin-2_src_install
  30
  31         insinto /etc/sudoers.d
  32         insopts -m440
  33         newins "${FILESDIR}/vdr-osdteletext.sudo" vdr-osdteletext
  34
  35         local vdr_user_home="/var/vdr"
  36         insinto "${vdr_user_home}/.local/share/fonts/"
  37         insopts -m444
  38         doins teletext2.ttf
  39         fowners -R vdr:vdr "${vdr_user_home}/.local"
  40 }
  41
  42 pkg_postinst() {
  43         elog "This ebuild has installed a special teletext font"
  44         elog "named \"teletext2\""
  45         elog "You may go to the plugin's setup menu and select"
  46         elog "the font."
  47 }