media-plugins/vdr-epgsearch/vdr-epgsearch-1.0.1_p20141227-r1.ebuild

   1 # Copyright 2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit vdr-plugin-2
   7
   8 DESCRIPTION="VDR plugin: create timers from epg content based on saved search expressions"
   9 HOMEPAGE="http://winni.vdr-developer.org/epgsearch"
  10
  11 case ${P#*_} in
  12         rc*|beta*)
  13                 MY_P="${P/_/.}"
  14                 SRC_URI="http://winni.vdr-developer.org/epgsearch/downloads/beta/${MY_P}.tgz"
  15                 S="${WORKDIR}/${MY_P#vdr-}"
  16                 ;;
  17         p*)
  18                 GIT_COMMIT_ID="a908daa4c5c6edd6c560ed96939358b4352e9b42"
  19                 GIT_COMMIT_DATE="20141227"
  20                 SRC_URI="http://projects.vdr-developer.org/git/vdr-plugin-epgsearch.git/snapshot/vdr-plugin-epgsearch-${GIT_COMMIT_ID}.tar.gz
  21                 -> ${P}.tar.gz"
  22                 S="${WORKDIR}/vdr-plugin-epgsearch-${GIT_COMMIT_ID}"
  23                 ;;
  24         *)
  25                 SRC_URI="http://winni.vdr-developer.org/epgsearch/downloads/${P}.tgz"
  26                 ;;
  27 esac
  28
  29 LICENSE="GPL-2+"
  30 SLOT="0"
  31 KEYWORDS="amd64 x86"
  32 IUSE="+conflictcheckonly +epgsearchonly l10n_de pcre +quicksearch tre"
  33 REQUIRED_USE="?? ( pcre tre )"
  34
  35 DEPEND="media-video/vdr
  36         pcre? ( dev-libs/libpcre )
  37         tre? ( dev-libs/tre )"
  38 RDEPEND="${DEPEND}"
  39 QA_FLAGS_IGNORED="usr/lib/vdr/plugins/libvdr-.* usr/lib64/vdr/plugins/libvdr-.* usr/bin/createcats"
  40
  41 src_prepare() {
  42         # make detection in vdr-plugin-2.eclass for new Makefile handling happy
  43         echo "# SOFILE" >> Makefile || die "cannot write to Makefile"
  44
  45         # remove untranslated .po files
  46         rm "${S}"/po/{ca_ES,da_DK,el_GR,et_EE,hr_HR,hu_HU,nn_NO,pl_PL,pt_PT,ro_RO,ru_RU,sl_SI,sv_SE,tr_TR}.po || die "cannot remove .po files"
  47
  48         local PATCHES=(
  49                 "${FILESDIR}/vdr-epgsearch-1.x.makefile.patch"
  50                 "${FILESDIR}/fix-manpage-generation.diff"
  51                 )
  52
  53         use conflictcheckonly || sed -e "s:install-\$(PLUGIN3)::" -i Makefile || die "cannot modify Makefile"
  54         use epgsearchonly || sed -e "s:install-\$(PLUGIN2)::" -i Makefile || die "cannot modify Makefile"
  55         use quicksearch || sed -e "s:install-\$(PLUGIN4)::" -i Makefile || die "cannot modify Makefile"
  56
  57         vdr-plugin-2_src_prepare
  58
  59         fix_vdr_libsi_include conflictcheck.c
  60
  61         # install conf-file disabled
  62         sed -e '/^Menu/s:^:#:' -i conf/epgsearchmenu.conf || die "cannot modify epgsearchmenu.conf"
  63
  64         # Get rid of the broken symlink
  65         rm README || die "cannot remove broken symlink"
  66 }
  67
  68 src_compile() {
  69         BUILD_PARAMS="SENDMAIL=/usr/bin/sendmail AUTOCONFIG=0"
  70
  71         if use pcre; then
  72                 BUILD_PARAMS+=" REGEXLIB=pcre"
  73                 einfo "Using pcre for regexp searches"
  74         fi
  75
  76         if use tre; then
  77                 BUILD_PARAMS+=" REGEXLIB=tre"
  78                 einfo "Using tre for unlimited fuzzy searches"
  79         fi
  80
  81         vdr-plugin-2_src_compile
  82 }
  83
  84 src_install() {
  85         DOCS=( conf/*.templ HISTORY* README.Translators )
  86         vdr-plugin-2_src_install
  87
  88         diropts -m 755 -o vdr -g vdr
  89         insopts -m 644 -o vdr -g vdr
  90         keepdir /etc/vdr/plugins/epgsearch
  91         insinto /etc/vdr/plugins/epgsearch
  92         doins conf/*
  93
  94         doman man/en/*
  95
  96         if use l10n_de; then
  97                 doman -i18n=de man/de/*
  98         fi
  99 }