media-plugins/gst-plugins-vaapi/gst-plugins-vaapi-0.6.1.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI="5"
   6
   7 inherit eutils multilib-minimal
   8
   9 MY_PN="gstreamer-vaapi"
  10 DESCRIPTION="Hardware accelerated video decoding through VA-API plugin"
  11 HOMEPAGE="https://github.com/01org/gstreamer-vaapi"
  12 SRC_URI="http://www.freedesktop.org/software/vaapi/releases/${MY_PN}/${MY_PN}-${PV}.tar.bz2"
  13
  14 LICENSE="LGPL-2.1"
  15 SLOT="1.0"
  16 KEYWORDS="~amd64 ~x86"
  17 IUSE="+drm opengl wayland +X"
  18 REQUIRED_USE="|| ( drm opengl wayland X )"
  19
  20 RDEPEND="
  21         >=dev-libs/glib-2.34.3:2[${MULTILIB_USEDEP}]
  22         >=media-libs/gstreamer-1.6:1.0[${MULTILIB_USEDEP}]
  23         >=media-libs/gst-plugins-base-1.6:1.0[${MULTILIB_USEDEP}]
  24         >=media-libs/gst-plugins-bad-1.6:1.0[opengl?,${MULTILIB_USEDEP}]
  25         >=x11-libs/libva-1.4.0[drm?,X?,opengl?,wayland?,${MULTILIB_USEDEP}]
  26         drm? (
  27                 >=virtual/libudev-208:=[${MULTILIB_USEDEP}]
  28                 >=x11-libs/libdrm-2.4.46[${MULTILIB_USEDEP}] )
  29         X? (
  30                 >=x11-libs/libX11-1.6.2[${MULTILIB_USEDEP}]
  31                 >=x11-libs/libXrandr-1.4.2[${MULTILIB_USEDEP}] )
  32         opengl? (
  33                 >=virtual/opengl-7.0-r1[${MULTILIB_USEDEP}]
  34                 >=x11-libs/libX11-1.6.2[${MULTILIB_USEDEP}]
  35                 >=x11-libs/libXrandr-1.4.2[${MULTILIB_USEDEP}] )
  36         wayland? ( >=dev-libs/wayland-1.0.6[${MULTILIB_USEDEP}] )
  37 "
  38 DEPEND="${RDEPEND}
  39         >=dev-util/gtk-doc-am-1.12
  40         >=virtual/pkgconfig-0-r1[${MULTILIB_USEDEP}]
  41 "
  42
  43 S="${WORKDIR}/${MY_PN}-${PV}"
  44
  45 multilib_src_configure() {
  46         ECONF_SOURCE=${S} \
  47         econf \
  48                 --enable-builtin-libvpx=no \
  49                 --disable-static \
  50                 --enable-egl \
  51                 $(use_enable drm) \
  52                 $(use_enable opengl glx) \
  53                 $(use_enable wayland) \
  54                 $(use_enable X x11)
  55 }
  56
  57 multilib_src_install_all() {
  58         einstalldocs
  59         prune_libtool_files --modules
  60 }