media-plugins/gst-plugins-smoothstreaming/gst-plugins-smoothstreaming-1.10.4.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 GST_ORG_MODULE=gst-plugins-bad
   6
   7 inherit gstreamer
   8
   9 DESCRIPTION="Smooth Streaming plugin for GStreamer"
  10 KEYWORDS="~amd64 ~x86"
  11 IUSE=""
  12
  13 RDEPEND=">=dev-libs/libxml2-2.9.1-r4[${MULTILIB_USEDEP}]"
  14 DEPEND="${RDEPEND}"
  15
  16 src_prepare() {
  17         default
  18
  19         # FIXME: gsturidownloader does not have a .pc
  20         #       gst-libs/gst/uridownloader:gsturidownloader \
  21         #       gst-libs/gst/adaptativedemux:gstadaptivedemux
  22         gstreamer_system_link \
  23                 gst-libs/gst/codecparsers:gstreamer-codecparsers
  24
  25         local directory libs
  26         directory="gst-libs/gst/uridownloader"
  27         libs="-lgobject-2.0 -lglib-2.0 -lgstreamer-1.0 -lgstbase-1.0 -lgsturidownloader-1.0"
  28         sed -e "s:\$(top_builddir)/${directory}/.*\.la:${libs}:" \
  29                 -i ext/smoothstreaming/Makefile.{am,in} || die
  30
  31         directory="gst-libs/gst/adaptivedemux"
  32         libs="-lgobject-2.0 -lglib-2.0 -lgstreamer-1.0 -lgstbase-1.0 -lgstapp-1.0 -lgsturidownloader-1.0 -lgstadaptivedemux-1.0"
  33         sed -e "s:\$(top_builddir)/${directory}/.*\.la:${libs}:" \
  34                 -i ext/smoothstreaming/Makefile.{am,in} || die
  35 }