media-plugins/gst-plugins-ffmpeg/gst-plugins-ffmpeg-0.10.13_p201211-r3.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6
   7 inherit eutils flag-o-matic multilib-minimal
   8
   9 MY_PN="gst-ffmpeg"
  10 MY_P=${MY_PN}-${PV}
  11
  12 # Create a major/minor combo for SLOT
  13 PVP=(${PV//[-\._]/ })
  14 SLOT=${PVP[0]}.${PVP[1]}
  15
  16 DESCRIPTION="FFmpeg based gstreamer plugin"
  17 HOMEPAGE="http://gstreamer.freedesktop.org/modules/gst-ffmpeg.html"
  18 #SRC_URI="http://gstreamer.freedesktop.org/src/${MY_PN}/${MY_P}.tar.bz2"
  19 SRC_URI="https://dev.gentoo.org/~tetromino/distfiles/${PN}/${MY_P}.tar.xz
  20         https://dev.gentoo.org/~tetromino/distfiles/${PN}/${MY_P}-libav-9-patches.tar.xz"
  21
  22 LICENSE="GPL-2"
  23 KEYWORDS="~alpha amd64 ~arm hppa ~ia64 ~mips ppc ppc64 ~sparc x86 ~amd64-fbsd ~x86-fbsd"
  24 IUSE="libav +orc"
  25
  26 S=${WORKDIR}/${MY_P}
  27
  28 RDEPEND="
  29         >=media-libs/gstreamer-0.10.36-r2:0.10[${MULTILIB_USEDEP}]
  30         >=media-libs/gst-plugins-base-0.10.36:0.10[${MULTILIB_USEDEP}]
  31
  32         !libav? ( >=media-video/ffmpeg-1.2.6-r1:0=[${MULTILIB_USEDEP}] )
  33         libav? (
  34                 >=media-video/libav-9.12:0=[${MULTILIB_USEDEP}]
  35                 <media-video/libav-10:0=[${MULTILIB_USEDEP}]
  36                 >=media-libs/libpostproc-10.20140517-r1:0=[${MULTILIB_USEDEP}] )
  37         orc? ( >=dev-lang/orc-0.4.17[${MULTILIB_USEDEP}] )
  38         abi_x86_32? ( !app-emulation/emul-linux-x86-gstplugins[-abi_x86_32(-)] )
  39 "
  40 DEPEND="${RDEPEND}
  41         >=virtual/pkgconfig-0-r1[${MULTILIB_USEDEP}]
  42 "
  43
  44 src_prepare() {
  45         sed -e 's/sleep 15//' -i configure.ac configure || die
  46
  47         # libav-9 support backported from gst-plugins-libav-1.1.0
  48         epatch ../${MY_P}-libav-9-patches/*.patch
  49
  50         # compat bits for older ffmpeg/libav releases
  51         epatch "${FILESDIR}/${PV}-channel_layout.patch" \
  52                 "${FILESDIR}/${PV}-iscodec.patch" \
  53                 "${FILESDIR}/${PV}-coma.patch" \
  54                 "${FILESDIR}/${PV}-gstffmpegpipe_redef.patch"
  55
  56         # compatibility with recent releases
  57         if has_version '>=media-video/ffmpeg-1.1' || has_version '>=media-video/libav-9' ; then
  58                 epatch "${FILESDIR}/${PV}-planaraudio.patch"
  59                 sed -i -e 's/ CODEC_ID/ AV_CODEC_ID/g' \
  60                            -e 's/ CodecID/ AVCodecID/g' \
  61                            ext/ffmpeg/*.{c,h}
  62                 epatch "${FILESDIR}/${PV}-ffmpeg2.patch"
  63         fi
  64 }
  65
  66 multilib_src_configure() {
  67         # always use system ffmpeg if possible
  68         ECONF_SOURCE=${S} \
  69         econf \
  70                 --with-system-ffmpeg \
  71                 $(use_enable orc)
  72 }
  73
  74 multilib_src_install_all() {
  75         einstalldocs
  76         prune_libtool_files --modules
  77 }