media-plugins/grilo-plugins/grilo-plugins-0.2.17.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI="5"
   5 GCONF_DEBUG="no" # --enable-debug only changes CFLAGS
   6 GNOME2_LA_PUNT="yes"
   7
   8 inherit gnome2
   9
  10 DESCRIPTION="A framework for easy media discovery and browsing"
  11 HOMEPAGE="https://wiki.gnome.org/Projects/Grilo"
  12
  13 LICENSE="LGPL-2.1+"
  14 SLOT="0.2"
  15 KEYWORDS="~alpha amd64 ~ppc ~ppc64 ~sparc x86"
  16 IUSE="daap +dvd flickr freebox gnome-online-accounts lua subtitles thetvdb tracker upnp-av +vimeo +youtube"
  17
  18 # Bump gom requirement to avoid segfaults
  19 RDEPEND="
  20         >=dev-libs/glib-2.44:2
  21         >=media-libs/grilo-0.2.12:${SLOT}[network,playlist]
  22         media-libs/libmediaart:2.0
  23         >=dev-libs/gom-0.3.1
  24
  25         dev-libs/gmime:2.6
  26         dev-libs/json-glib
  27         dev-libs/libxml2:2
  28         dev-db/sqlite:3
  29
  30         daap? ( >=net-libs/libdmapsharing-2.9.12:3.0 )
  31         dvd? ( >=dev-libs/totem-pl-parser-3.4.1 )
  32         flickr? ( net-libs/liboauth )
  33         freebox? ( net-dns/avahi )
  34         gnome-online-accounts? ( >=net-libs/gnome-online-accounts-3.17.91 )
  35         lua? (
  36                 >=dev-lang/lua-5.3
  37                 app-arch/libarchive
  38                 dev-libs/libxml2:2
  39                 >=dev-libs/totem-pl-parser-3.4.1 )
  40         subtitles? ( net-libs/libsoup:2.4 )
  41         thetvdb? (
  42                 app-arch/libarchive
  43                 dev-libs/libxml2 )
  44         tracker? ( >=app-misc/tracker-0.10.5:= )
  45         youtube? (
  46                 >=dev-libs/libgdata-0.9.1:=
  47                 >=dev-libs/totem-pl-parser-3.4.1 )
  48         upnp-av? (
  49                 net-libs/libsoup:2.4
  50                 net-libs/dleyna-connector-dbus )
  51         vimeo? (
  52                 >=dev-libs/totem-pl-parser-3.4.1 )
  53 "
  54 DEPEND="${RDEPEND}
  55         app-text/docbook-xml-dtd:4.5
  56         app-text/yelp-tools
  57         >=dev-util/intltool-0.40.0
  58         virtual/pkgconfig
  59 "
  60
  61 # FIXME: some unittests required python-dbusmock
  62 src_configure() {
  63         # --enable-debug only changes CFLAGS, useless for us
  64         # Plugins
  65         # shoutcast seems to be broken
  66         gnome2_src_configure \
  67                 --disable-static \
  68                 --disable-debug \
  69                 --disable-uninstalled \
  70                 --enable-bookmarks \
  71                 --enable-filesystem \
  72                 --enable-gravatar \
  73                 --enable-jamendo \
  74                 --enable-localmetadata \
  75                 --enable-magnatune \
  76                 --enable-metadata-store \
  77                 --enable-podcasts \
  78                 --enable-raitv \
  79                 --disable-shoutcast \
  80                 --enable-tmdb \
  81                 $(use_enable daap dmap) \
  82                 $(use_enable dvd optical-media) \
  83                 $(use_enable flickr) \
  84                 $(use_enable freebox) \
  85                 $(use_enable gnome-online-accounts goa) \
  86                 $(use_enable lua lua-factory) \
  87                 $(use_enable subtitles opensubtitles) \
  88                 $(use_enable thetvdb) \
  89                 $(use_enable tracker) \
  90                 $(use_enable upnp-av dleyna) \
  91                 $(use_enable vimeo) \
  92                 $(use_enable youtube)
  93 }