media-plugins/audacious-plugins/audacious-plugins-9999.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 MY_P="${P/_/-}"
   7
   8 if [[ ${PV} == *9999 ]]; then
   9         inherit autotools git-r3
  10         EGIT_REPO_URI="https://github.com/audacious-media-player/audacious-plugins.git"
  11 else
  12         SRC_URI="https://distfiles.audacious-media-player.org/${MY_P}.tar.bz2"
  13         KEYWORDS="~amd64 ~x86"
  14 fi
  15 DESCRIPTION="Lightweight and versatile audio player"
  16 HOMEPAGE="https://audacious-media-player.org/"
  17
  18 LICENSE="GPL-2"
  19 SLOT="0"
  20 IUSE="aac +alsa ampache bs2b cdda cue ffmpeg flac fluidsynth gme gtk http
  21         jack lame libav libnotify libsamplerate lirc mms modplug mp3 nls opengl
  22         pulseaudio qtmedia scrobbler sdl sid sndfile soxr speedpitch streamtuner
  23         vorbis wavpack"
  24 REQUIRED_USE="
  25         || ( alsa jack pulseaudio qtmedia sdl )
  26         ampache? ( http ) streamtuner? ( http )
  27         gtk? ( !ampache !qtmedia !streamtuner )"
  28
  29 # The following plugins REQUIRE a GUI build of audacious, because non-GUI
  30 # builds do NOT install the libaudgui library & headers.
  31 # Plugins without a configure option:
  32 #   alarm
  33 #   albumart
  34 #   delete-files
  35 #   ladspa
  36 #   playlist-manager
  37 #   search-tool
  38 #   skins
  39 #   vtx
  40 # Plugins with a configure option:
  41 #   glspectrum
  42 #   gtkui
  43 #   hotkey
  44 #   notify
  45 #   statusicon
  46 BDEPEND="
  47         dev-util/gdbus-codegen
  48         virtual/pkgconfig
  49         nls? ( dev-util/intltool )
  50 "
  51 DEPEND="
  52         app-arch/unzip
  53         dev-libs/dbus-glib
  54         dev-libs/glib
  55         dev-libs/libxml2:2
  56         ~media-sound/audacious-${PV}[gtk=]
  57         aac? ( >=media-libs/faad2-2.7 )
  58         alsa? ( >=media-libs/alsa-lib-1.0.16 )
  59         ampache? ( =media-libs/ampache_browser-1* )
  60         bs2b? ( media-libs/libbs2b )
  61         cdda? (
  62                 dev-libs/libcdio:=
  63                 dev-libs/libcdio-paranoia:=
  64                 >=media-libs/libcddb-1.2.1
  65         )
  66         cue? ( media-libs/libcue:= )
  67         ffmpeg? ( >=virtual/ffmpeg-0.7.3 )
  68         flac? (
  69                 >=media-libs/flac-1.2.1-r1
  70                 >=media-libs/libvorbis-1.0
  71         )
  72         fluidsynth? ( media-sound/fluidsynth:= )
  73         gtk? (
  74                 x11-libs/gtk+:2
  75                 x11-libs/libXcomposite
  76                 x11-libs/libXrender
  77         )
  78         !gtk? (
  79                 dev-qt/qtcore:5
  80                 dev-qt/qtgui:5
  81                 dev-qt/qtwidgets:5
  82                 opengl? ( dev-qt/qtopengl:5 )
  83         )
  84         http? ( >=net-libs/neon-0.26.4 )
  85         jack? (
  86                 >=media-libs/bio2jack-0.4
  87                 virtual/jack
  88         )
  89         lame? ( media-sound/lame )
  90         libnotify? ( x11-libs/libnotify )
  91         libsamplerate? ( media-libs/libsamplerate:= )
  92         lirc? ( app-misc/lirc )
  93         mms? ( >=media-libs/libmms-0.3 )
  94         modplug? ( media-libs/libmodplug )
  95         mp3? ( >=media-sound/mpg123-1.12.1 )
  96         pulseaudio? ( >=media-sound/pulseaudio-0.9.3 )
  97         qtmedia? ( dev-qt/qtmultimedia:5 )
  98         scrobbler? ( net-misc/curl )
  99         sdl? ( media-libs/libsdl2[sound] )
 100         sid? ( >=media-libs/libsidplayfp-1.0.0 )
 101         sndfile? ( >=media-libs/libsndfile-1.0.17-r1 )
 102         soxr? ( media-libs/soxr )
 103         speedpitch? ( media-libs/libsamplerate:= )
 104         streamtuner? ( dev-qt/qtnetwork:5 )
 105         vorbis? (
 106                 >=media-libs/libogg-1.1.3
 107                 >=media-libs/libvorbis-1.2.0
 108         )
 109         wavpack? ( >=media-sound/wavpack-4.50.1-r1 )
 110 "
 111 RDEPEND="${DEPEND}"
 112
 113 S="${WORKDIR}/${MY_P}"
 114
 115 pkg_setup() {
 116         use mp3 || ewarn "MP3 support is optional, you may want to enable the mp3 USE-flag"
 117 }
 118
 119 src_prepare() {
 120         default
 121         if ! use nls; then
 122                 sed -e "/SUBDIRS/s/ po//" -i Makefile || die # bug #512698
 123         fi
 124         [[ ${PV} == *9999 ]] && eautoreconf
 125 }
 126
 127 src_configure() {
 128         local myeconfargs=(
 129                 --enable-mpris2
 130                 --enable-songchange
 131                 --disable-adplug # not packaged
 132                 --disable-openmpt # not packaged
 133                 --disable-oss4
 134                 --disable-coreaudio
 135                 --disable-sndio
 136                 $(use_enable aac)
 137                 $(use_enable alsa)
 138                 $(use_enable ampache)
 139                 $(use_enable bs2b)
 140                 $(use_enable cdda cdaudio)
 141                 $(use_enable cue)
 142                 $(use_enable flac)
 143                 $(use_enable flac filewriter)
 144                 $(use_enable fluidsynth amidiplug)
 145                 $(use_enable gme console)
 146                 $(use_enable gtk aosd)
 147                 $(use_enable gtk gtk)
 148                 $(use_enable gtk hotkey)
 149                 $(use_enable !gtk qt)
 150                 $(use_enable http neon)
 151                 $(use_enable jack)
 152                 $(use_enable lame filewriter_mp3)
 153                 $(use_enable libnotify notify)
 154                 $(use_enable libsamplerate resample)
 155                 $(use_enable lirc)
 156                 $(use_enable mms)
 157                 $(use_enable modplug)
 158                 $(use_enable mp3 mpg123)
 159                 $(use_enable nls)
 160                 $(use_enable pulseaudio pulse)
 161                 $(use_enable qtmedia qtaudio)
 162                 $(use_enable scrobbler scrobbler2)
 163                 $(use_enable sdl sdlout)
 164                 $(use_enable sid)
 165                 $(use_enable sndfile)
 166                 $(use_enable soxr)
 167                 $(use_enable speedpitch)
 168                 $(use_enable streamtuner)
 169                 $(use_enable vorbis)
 170                 $(use_enable wavpack)
 171                 $(use_with ffmpeg ffmpeg $(usex libav libav ffmpeg))
 172         )
 173         use !gtk && myeconfargs+=(
 174                 $(usex opengl --enable-qtglspectrum --disable-qtglspectrum)
 175         )
 176
 177         econf "${myeconfargs[@]}"
 178 }