media-plugins/audacious-plugins/audacious-plugins-4.0.3.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 MY_P="${P/_/-}"
   7
   8 if [[ ${PV} == *9999 ]]; then
   9         inherit autotools git-r3
  10         EGIT_REPO_URI="https://github.com/audacious-media-player/audacious-plugins.git"
  11 else
  12         SRC_URI="https://distfiles.audacious-media-player.org/${MY_P}.tar.bz2"
  13         KEYWORDS="amd64 x86"
  14 fi
  15 DESCRIPTION="Lightweight and versatile audio player"
  16 HOMEPAGE="https://audacious-media-player.org/"
  17
  18 LICENSE="GPL-2"
  19 SLOT="0"
  20 IUSE="aac +alsa ampache bs2b cdda cue ffmpeg flac fluidsynth gme http jack lame
  21         libnotify libsamplerate lirc mms modplug mp3 nls opengl pulseaudio qtmedia
  22         scrobbler sdl sid sndfile soxr speedpitch streamtuner vorbis wavpack"
  23 REQUIRED_USE="
  24         || ( alsa jack pulseaudio qtmedia sdl )
  25         ampache? ( http ) streamtuner? ( http )"
  26
  27 # The following plugins REQUIRE a GUI build of audacious, because non-GUI
  28 # builds do NOT install the libaudgui library & headers.
  29 # Plugins without a configure option:
  30 #   alarm
  31 #   albumart
  32 #   delete-files
  33 #   ladspa
  34 #   playlist-manager
  35 #   search-tool
  36 #   skins
  37 #   vtx
  38 # Plugins with a configure option:
  39 #   glspectrum
  40 #   gtkui
  41 #   hotkey
  42 #   notify
  43 #   statusicon
  44 BDEPEND="
  45         dev-util/gdbus-codegen
  46         virtual/pkgconfig
  47         nls? ( dev-util/intltool )
  48 "
  49 DEPEND="
  50         app-arch/unzip
  51         dev-libs/dbus-glib
  52         dev-libs/glib
  53         dev-libs/libxml2:2
  54         dev-qt/qtcore:5
  55         dev-qt/qtgui:5
  56         dev-qt/qtwidgets:5
  57         ~media-sound/audacious-${PV}
  58         aac? ( >=media-libs/faad2-2.7 )
  59         alsa? ( >=media-libs/alsa-lib-1.0.16 )
  60         ampache? ( =media-libs/ampache_browser-1* )
  61         bs2b? ( media-libs/libbs2b )
  62         cdda? (
  63                 dev-libs/libcdio:=
  64                 dev-libs/libcdio-paranoia:=
  65                 >=media-libs/libcddb-1.2.1
  66         )
  67         cue? ( media-libs/libcue:= )
  68         ffmpeg? ( >=media-video/ffmpeg-0.7.3 )
  69         flac? (
  70                 >=media-libs/flac-1.2.1-r1
  71                 >=media-libs/libvorbis-1.0
  72         )
  73         fluidsynth? ( media-sound/fluidsynth:= )
  74         http? ( >=net-libs/neon-0.26.4 )
  75         jack? (
  76                 >=media-libs/bio2jack-0.4
  77                 virtual/jack
  78         )
  79         lame? ( media-sound/lame )
  80         libnotify? ( x11-libs/libnotify )
  81         libsamplerate? ( media-libs/libsamplerate:= )
  82         lirc? ( app-misc/lirc )
  83         mms? ( >=media-libs/libmms-0.3 )
  84         modplug? ( media-libs/libmodplug )
  85         mp3? ( >=media-sound/mpg123-1.12.1 )
  86         opengl? ( dev-qt/qtopengl:5 )
  87         pulseaudio? ( >=media-sound/pulseaudio-0.9.3 )
  88         qtmedia? ( dev-qt/qtmultimedia:5 )
  89         scrobbler? ( net-misc/curl )
  90         sdl? ( media-libs/libsdl2[sound] )
  91         sid? ( >=media-libs/libsidplayfp-1.0.0 )
  92         sndfile? ( >=media-libs/libsndfile-1.0.17-r1 )
  93         soxr? ( media-libs/soxr )
  94         speedpitch? ( media-libs/libsamplerate:= )
  95         streamtuner? ( dev-qt/qtnetwork:5 )
  96         vorbis? (
  97                 >=media-libs/libogg-1.1.3
  98                 >=media-libs/libvorbis-1.2.0
  99         )
 100         wavpack? ( >=media-sound/wavpack-4.50.1-r1 )
 101 "
 102 RDEPEND="${DEPEND}"
 103
 104 S="${WORKDIR}/${MY_P}"
 105
 106 pkg_setup() {
 107         use mp3 || ewarn "MP3 support is optional, you may want to enable the mp3 USE-flag"
 108 }
 109
 110 src_prepare() {
 111         default
 112         if ! use nls; then
 113                 sed -e "/SUBDIRS/s/ po//" -i Makefile || die # bug #512698
 114         fi
 115         [[ ${PV} == *9999 ]] && eautoreconf
 116 }
 117
 118 src_configure() {
 119         local myeconfargs=(
 120                 --enable-mpris2
 121                 --enable-qt
 122                 --enable-songchange
 123                 --disable-adplug # not packaged
 124                 --disable-gtk
 125                 --disable-openmpt # not packaged
 126                 --disable-oss4
 127                 --disable-coreaudio
 128                 --disable-sndio
 129                 $(use_enable aac)
 130                 $(use_enable alsa)
 131                 $(use_enable ampache)
 132                 $(use_enable bs2b)
 133                 $(use_enable cdda cdaudio)
 134                 $(use_enable cue)
 135                 $(use_enable flac)
 136                 $(use_enable flac filewriter)
 137                 $(use_enable fluidsynth amidiplug)
 138                 $(use_enable gme console)
 139                 $(use_enable http neon)
 140                 $(use_enable jack)
 141                 $(use_enable lame filewriter_mp3)
 142                 $(use_enable libnotify notify)
 143                 $(use_enable libsamplerate resample)
 144                 $(use_enable lirc)
 145                 $(use_enable mms)
 146                 $(use_enable modplug)
 147                 $(use_enable mp3 mpg123)
 148                 $(use_enable nls)
 149                 $(use_enable opengl qtglspectrum)
 150                 $(use_enable pulseaudio pulse)
 151                 $(use_enable qtmedia qtaudio)
 152                 $(use_enable scrobbler scrobbler2)
 153                 $(use_enable sdl sdlout)
 154                 $(use_enable sid)
 155                 $(use_enable sndfile)
 156                 $(use_enable soxr)
 157                 $(use_enable speedpitch)
 158                 $(use_enable streamtuner)
 159                 $(use_enable vorbis)
 160                 $(use_enable wavpack)
 161                 $(use_with ffmpeg ffmpeg ffmpeg)
 162         )
 163
 164         econf "${myeconfargs[@]}"
 165 }