media-plugins/audacious-plugins/audacious-plugins-3.9.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 MY_P="${P/_/-}"
   7
   8 DESCRIPTION="Audacious Player - Your music, your way, no exceptions"
   9 HOMEPAGE="http://audacious-media-player.org/"
  10
  11 if [[ ${PV} == *9999 ]]; then
  12         inherit autotools git-r3
  13         EGIT_REPO_URI="https://github.com/audacious-media-player/audacious-plugins.git"
  14 else
  15         SRC_URI="
  16                 !gtk3? ( http://distfiles.audacious-media-player.org/${MY_P}.tar.bz2 )
  17                 gtk3? ( http://distfiles.audacious-media-player.org/${MY_P}-gtk3.tar.bz2 )"
  18         KEYWORDS="~amd64 ~x86"
  19 fi
  20
  21 LICENSE="GPL-2"
  22 SLOT="0"
  23 IUSE="aac +adplug alsa ampache aosd bs2b cdda cue ffmpeg flac fluidsynth gnome hotkeys http gme gtk gtk3 jack lame libav
  24         libnotify libsamplerate lirc mms modplug mp3 nls pulseaudio qt5 scrobbler sdl sid sndfile soxr vorbis wavpack"
  25 REQUIRED_USE="
  26         ^^ ( gtk gtk3 qt5 )
  27         qt5? ( !libnotify )
  28         || ( alsa jack pulseaudio sdl )"
  29
  30 # The following plugins REQUIRE a GUI build of audacious, because non-GUI
  31 # builds do NOT install the libaudgui library & headers.
  32 # Plugins without a configure option:
  33 #   alarm
  34 #   albumart
  35 #   delete-files
  36 #   ladspa
  37 #   playlist-manager
  38 #   search-tool
  39 #   skins
  40 #   vtx
  41 # Plugins with a configure option:
  42 #   glspectrum
  43 #   gtkui
  44 #   hotkey
  45 #   notify
  46 #   statusicon
  47 RDEPEND="
  48         app-arch/unzip
  49         dev-libs/dbus-glib
  50         dev-libs/glib[utils]
  51         dev-libs/libxml2:2
  52         ~media-sound/audacious-${PV}[gtk?,gtk3?,qt5?]
  53         aac? ( >=media-libs/faad2-2.7 )
  54         alsa? ( >=media-libs/alsa-lib-1.0.16 )
  55         ampache? ( www-apps/ampache )
  56         aosd? (
  57                 x11-libs/libXrender
  58                 x11-libs/libXcomposite
  59         )
  60         bs2b? ( media-libs/libbs2b )
  61         cdda? (
  62                 >=media-libs/libcddb-1.2.1
  63                 dev-libs/libcdio-paranoia
  64         )
  65         cue? ( media-libs/libcue )
  66         ffmpeg? ( >=virtual/ffmpeg-0.7.3 )
  67         flac? (
  68                 >=media-libs/libvorbis-1.0
  69                 >=media-libs/flac-1.2.1-r1
  70         )
  71         fluidsynth? ( media-sound/fluidsynth )
  72         http? ( >=net-libs/neon-0.26.4 )
  73         gtk? ( x11-libs/gtk+:2 )
  74         gtk3? ( x11-libs/gtk+:3 )
  75         qt5? (
  76                 dev-qt/qtcore:5
  77                 dev-qt/qtgui:5
  78                 dev-qt/qtmultimedia:5
  79                 dev-qt/qtwidgets:5
  80                 media-libs/adplug
  81         )
  82         jack? (
  83                 >=media-libs/bio2jack-0.4
  84                 media-sound/jack-audio-connection-kit
  85         )
  86         lame? ( media-sound/lame )
  87         libnotify? ( x11-libs/libnotify )
  88         libsamplerate? ( media-libs/libsamplerate )
  89         lirc? ( app-misc/lirc )
  90         mms? ( >=media-libs/libmms-0.3 )
  91         modplug? ( media-libs/libmodplug )
  92         mp3? ( >=media-sound/mpg123-1.12.1 )
  93         pulseaudio? ( >=media-sound/pulseaudio-0.9.3 )
  94         scrobbler? ( net-misc/curl )
  95         sdl? ( media-libs/libsdl2[sound] )
  96         sid? ( >=media-libs/libsidplayfp-1.0.0 )
  97         sndfile? ( >=media-libs/libsndfile-1.0.17-r1 )
  98         soxr? ( media-libs/soxr )
  99         vorbis? (
 100                 >=media-libs/libvorbis-1.2.0
 101                 >=media-libs/libogg-1.1.3
 102         )
 103         wavpack? ( >=media-sound/wavpack-4.50.1-r1 )"
 104
 105 DEPEND="${RDEPEND}
 106         dev-util/gdbus-codegen
 107         virtual/pkgconfig
 108         nls? ( dev-util/intltool )"
 109
 110 S="${WORKDIR}/${MY_P}"
 111
 112 src_unpack() {
 113         if [[ ${PV} == *9999 ]]; then
 114                 git-r3_src_unpack
 115         else
 116                 default
 117                 if use gtk3; then
 118                         mv "${MY_P}"{-gtk3,} || die
 119                 fi
 120         fi
 121 }
 122
 123 src_prepare() {
 124         default
 125         [[ ${PV} == *9999 ]] && eautoreconf
 126 }
 127
 128 src_configure() {
 129         if ! use mp3 ; then
 130                 ewarn "MP3 support is optional, you may want to enable the mp3 USE-flag"
 131         fi
 132
 133         econf \
 134                 --enable-mpris2 \
 135                 --enable-songchange \
 136                 --enable-speedpitch \
 137                 --disable-oss4 \
 138                 --disable-qtaudio \
 139                 --disable-qtglspectrum \
 140                 --disable-coreaudio \
 141                 --disable-sndio \
 142                 $(use_enable aac) \
 143                 $(use_enable alsa) \
 144                 $(use_enable ampache) \
 145                 $(use_enable aosd) \
 146                 $(use_enable bs2b) \
 147                 $(use_enable cdda cdaudio) \
 148                 $(use_enable cue) \
 149                 $(use_enable flac) \
 150                 $(use_enable fluidsynth amidiplug) \
 151                 $(use_enable flac filewriter) \
 152                 $(use_enable gme console) \
 153                 $(use_enable $(usex gtk gtk gtk3) gtk) \
 154                 $(use_enable hotkeys hotkey) \
 155                 $(use_enable http neon) \
 156                 $(use_enable jack) \
 157                 $(use_enable gnome gnomeshortcuts) \
 158                 $(use_enable lame filewriter_mp3) \
 159                 $(use_enable libnotify notify) \
 160                 $(use_enable libsamplerate resample) \
 161                 $(use_enable lirc) \
 162                 $(use_enable mms) \
 163                 $(use_enable modplug) \
 164                 $(use_enable mp3 mpg123) \
 165                 $(use_enable nls) \
 166                 $(use_enable pulseaudio pulse) \
 167                 $(use_enable qt5 qt) \
 168                 $(use_enable scrobbler scrobbler2) \
 169                 $(use_enable sdl sdlout) \
 170                 $(use_enable sid) \
 171                 $(use_enable sndfile) \
 172                 $(use_enable soxr) \
 173                 $(use_enable vorbis) \
 174                 $(use_enable wavpack) \
 175                 $(use_with ffmpeg ffmpeg $(usex libav libav ffmpeg))
 176 }