media-plugins/audacious-plugins/audacious-plugins-3.10.ebuild

   1 # Copyright 1999-2018 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 MY_P="${P/_/-}"
   7
   8 DESCRIPTION="Lightweight and versatile audio player"
   9 HOMEPAGE="https://audacious-media-player.org/"
  10
  11 if [[ ${PV} == *9999 ]]; then
  12         inherit autotools git-r3
  13         EGIT_REPO_URI="https://github.com/audacious-media-player/audacious-plugins.git"
  14 else
  15         SRC_URI="https://distfiles.audacious-media-player.org/${MY_P}.tar.bz2"
  16         KEYWORDS="~amd64 ~x86"
  17 fi
  18
  19 LICENSE="GPL-2"
  20 SLOT="0"
  21 IUSE="aac +adplug alsa ampache aosd bs2b cdda cue ffmpeg flac fluidsynth http gme jack lame libav
  22         libnotify libsamplerate lirc mms modplug mp3 nls pulseaudio scrobbler sdl sid sndfile soxr speedpitch vorbis wavpack"
  23 REQUIRED_USE="
  24         || ( alsa jack pulseaudio sdl )
  25         ampache? ( http )"
  26
  27 # The following plugins REQUIRE a GUI build of audacious, because non-GUI
  28 # builds do NOT install the libaudgui library & headers.
  29 # Plugins without a configure option:
  30 #   alarm
  31 #   albumart
  32 #   delete-files
  33 #   ladspa
  34 #   playlist-manager
  35 #   search-tool
  36 #   skins
  37 #   vtx
  38 # Plugins with a configure option:
  39 #   glspectrum
  40 #   gtkui
  41 #   hotkey
  42 #   notify
  43 #   statusicon
  44 RDEPEND="
  45         app-arch/unzip
  46         dev-libs/dbus-glib
  47         dev-libs/glib
  48         dev-libs/libxml2:2
  49         dev-qt/qtcore:5
  50         dev-qt/qtgui:5
  51         dev-qt/qtmultimedia:5
  52         dev-qt/qtwidgets:5
  53         media-libs/adplug
  54         ~media-sound/audacious-${PV}
  55         aac? ( >=media-libs/faad2-2.7 )
  56         alsa? ( >=media-libs/alsa-lib-1.0.16 )
  57         ampache? ( =media-libs/ampache_browser-1* )
  58         aosd? (
  59                 x11-libs/libXrender
  60                 x11-libs/libXcomposite
  61         )
  62         bs2b? ( media-libs/libbs2b )
  63         cdda? (
  64                 >=media-libs/libcddb-1.2.1
  65                 dev-libs/libcdio-paranoia
  66         )
  67         cue? ( media-libs/libcue )
  68         ffmpeg? ( >=virtual/ffmpeg-0.7.3 )
  69         flac? (
  70                 >=media-libs/libvorbis-1.0
  71                 >=media-libs/flac-1.2.1-r1
  72         )
  73         fluidsynth? ( media-sound/fluidsynth )
  74         http? ( >=net-libs/neon-0.26.4 )
  75         jack? (
  76                 >=media-libs/bio2jack-0.4
  77                 virtual/jack
  78         )
  79         lame? ( media-sound/lame )
  80         libsamplerate? ( media-libs/libsamplerate:= )
  81         lirc? ( app-misc/lirc )
  82         mms? ( >=media-libs/libmms-0.3 )
  83         modplug? ( media-libs/libmodplug )
  84         mp3? ( >=media-sound/mpg123-1.12.1 )
  85         pulseaudio? ( >=media-sound/pulseaudio-0.9.3 )
  86         scrobbler? ( net-misc/curl )
  87         sdl? ( media-libs/libsdl2[sound] )
  88         sid? ( >=media-libs/libsidplayfp-1.0.0 )
  89         sndfile? ( >=media-libs/libsndfile-1.0.17-r1 )
  90         soxr? ( media-libs/soxr )
  91         speedpitch? ( media-libs/libsamplerate:= )
  92         vorbis? (
  93                 >=media-libs/libvorbis-1.2.0
  94                 >=media-libs/libogg-1.1.3
  95         )
  96         wavpack? ( >=media-sound/wavpack-4.50.1-r1 )"
  97
  98 DEPEND="${RDEPEND}
  99         dev-util/gdbus-codegen
 100         virtual/pkgconfig
 101         nls? ( dev-util/intltool )"
 102
 103 PATCHES=( "${FILESDIR}/${P}-fix-slow-search.patch" )
 104
 105 S="${WORKDIR}/${MY_P}"
 106
 107 src_configure() {
 108         if ! use mp3 ; then
 109                 ewarn "MP3 support is optional, you may want to enable the mp3 USE-flag"
 110         fi
 111
 112         econf \
 113                 --enable-mpris2 \
 114                 --enable-qt \
 115                 --enable-qtaudio \
 116                 --enable-songchange \
 117                 --disable-coreaudio \
 118                 --disable-gtk \
 119                 --disable-hotkey \
 120                 --disable-notify \
 121                 --disable-oss4 \
 122                 --disable-qtglspectrum \
 123                 --disable-sndio \
 124                 $(use_enable aac) \
 125                 $(use_enable alsa) \
 126                 $(use_enable ampache) \
 127                 $(use_enable aosd) \
 128                 $(use_enable bs2b) \
 129                 $(use_enable cdda cdaudio) \
 130                 $(use_enable cue) \
 131                 $(use_enable flac) \
 132                 $(use_enable fluidsynth amidiplug) \
 133                 $(use_enable flac filewriter) \
 134                 $(use_enable gme console) \
 135                 $(use_enable http neon) \
 136                 $(use_enable jack) \
 137                 $(use_enable lame filewriter_mp3) \
 138                 $(use_enable libsamplerate resample) \
 139                 $(use_enable lirc) \
 140                 $(use_enable mms) \
 141                 $(use_enable modplug) \
 142                 $(use_enable mp3 mpg123) \
 143                 $(use_enable nls) \
 144                 $(use_enable pulseaudio pulse) \
 145                 $(use_enable scrobbler scrobbler2) \
 146                 $(use_enable sdl sdlout) \
 147                 $(use_enable sid) \
 148                 $(use_enable sndfile) \
 149                 $(use_enable soxr) \
 150                 $(use_enable speedpitch) \
 151                 $(use_enable vorbis) \
 152                 $(use_enable wavpack) \
 153                 $(use_with ffmpeg ffmpeg $(usex libav libav ffmpeg))
 154 }