media-libs/opengtl/opengtl-0.9.18.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6
   7 MY_P="OpenGTL-${PV}"
   8
   9 inherit cmake-utils
  10
  11 DESCRIPTION="Collection of libraries for graphics transformation algorithms"
  12 HOMEPAGE="http://opengtl.org/"
  13 SRC_URI="http://download.opengtl.org/${MY_P}.tar.bz2 https://dev.gentoo.org/~creffett/distfiles/${PN}-0.9.18-llvm-3.3.patch"
  14
  15 LICENSE="LGPL-2"
  16 SLOT="0"
  17 KEYWORDS="amd64 ~arm x86"
  18 IUSE="debug test"
  19
  20 RDEPEND="
  21         media-libs/libpng:0=
  22         (
  23                 <sys-devel/llvm-3.4
  24                 >=sys-devel/llvm-3.1
  25         )
  26 "
  27 DEPEND="${RDEPEND}
  28         app-text/ghostscript-gpl
  29         test? ( dev-util/lcov )
  30 "
  31
  32 RESTRICT="test"
  33
  34 S=${WORKDIR}/${MY_P}
  35
  36 PATCHES=(
  37         "${FILESDIR}/${PN}-0.9.18-memcpy.patch"
  38         "${FILESDIR}/${PN}-0.9.18-underlinking.patch"
  39 )
  40
  41 src_prepare() {
  42         if has_version ">=sys-devel/llvm-3.3"; then
  43                 epatch "${DISTDIR}/${PN}-0.9.18-llvm-3.3.patch"
  44         fi
  45         cmake-utils_src_prepare
  46 }
  47
  48 src_configure() {
  49         local mycmakeargs=(
  50                 -DCMAKE_INSTALL_RPATH_USE_LINK_PATH=TRUE
  51                 $(cmake-utils_use debug OPENGTL_ENABLE_DEBUG_OUTPUT)
  52                 $(cmake-utils_use test OPENGTL_BUILD_TESTS)
  53                 $(cmake-utils_use test OPENGTL_CODE_COVERAGE)
  54         )
  55         cmake-utils_src_configure
  56 }
  57
  58 src_install() {
  59         cmake-utils_src_install
  60         newdoc OpenShiva/doc/reference/region.pdf OpenShiva.pdf
  61 }