media-libs/openexr/openexr-2.1.0.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=5
   5 inherit autotools-multilib
   6
   7 DESCRIPTION="ILM's OpenEXR high dynamic-range image file format libraries"
   8 HOMEPAGE="http://openexr.com/"
   9 SRC_URI="http://download.savannah.gnu.org/releases/openexr/${P}.tar.gz"
  10
  11 LICENSE="BSD"
  12 SLOT="0/21" # 21 from SONAME
  13 KEYWORDS="amd64 -arm hppa ia64 ppc ppc64 ~sparc x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~x86-solaris"
  14 IUSE="examples static-libs"
  15
  16 RDEPEND=">=sys-libs/zlib-1.2.8-r1:=[${MULTILIB_USEDEP}]
  17         >=media-libs/ilmbase-${PV}:=[${MULTILIB_USEDEP}]"
  18 DEPEND="${RDEPEND}
  19         virtual/pkgconfig"
  20 DOCS=( AUTHORS ChangeLog NEWS README )
  21
  22 src_prepare() {
  23         # Fix path for testsuite
  24         sed -i -e "s:/var/tmp/:${T}:" IlmImfTest/tmpDir.h || die
  25         autotools-multilib_src_prepare
  26 }
  27
  28 src_configure() {
  29         local myeconfargs=(
  30                 $(use_enable static-libs static)
  31                 $(use_enable examples imfexamples)
  32         )
  33         autotools-multilib_src_configure
  34 }
  35
  36 src_install() {
  37         autotools-multilib_src_install \
  38                 docdir="${EPREFIX}"/usr/share/doc/${PF}/pdf \
  39                 examplesdir="${EPREFIX}"/usr/share/doc/${PF}/examples
  40
  41         docompress -x /usr/share/doc/${PF}/examples
  42
  43         if ! use examples; then
  44                 rm -rf "${ED}"/usr/share/doc/${PF}/examples
  45         fi
  46 }