media-libs/libyami/libyami-1.2.0.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=5
   5
   6 SCM=""
   7 if [ "${PV#9999}" != "${PV}" ] ; then
   8         SCM=git-r3
   9         EGIT_REPO_URI="https://github.com/01org/libyami"
  10 fi
  11
  12 inherit ${SCM} autotools multilib-minimal flag-o-matic
  13
  14 DESCRIPTION="Yet Another Media Infrastructure: Media codec with hardware acceleration"
  15 HOMEPAGE="https://github.com/01org/libyami"
  16
  17 if [ "${PV#9999}" != "${PV}" ] ; then
  18         KEYWORDS=""
  19         SRC_URI=""
  20 else
  21         KEYWORDS="~amd64"
  22         SRC_URI="https://github.com/01org/libyami/archive/${PV}.tar.gz -> ${P}.tar.gz"
  23 fi
  24
  25 LICENSE="Apache-2.0"
  26 SLOT="0"
  27 IUSE="debug egl dmabuf doc md5 v4l X test wayland"
  28 RESTRICT="!test? ( test )"
  29
  30 RDEPEND="
  31         >=x11-libs/libva-1.7.2[drm,X?,wayland?,${MULTILIB_USEDEP}]
  32         v4l? (
  33                 >=virtual/opengl-7[${MULTILIB_USEDEP}]
  34                 >=media-libs/libv4l-1.6.2[${MULTILIB_USEDEP}]
  35                 >=media-libs/mesa-10[egl,gles2,${MULTILIB_USEDEP}]
  36         )
  37         X? ( >=x11-libs/libX11-1.6.2[${MULTILIB_USEDEP}] )
  38         md5? ( dev-libs/openssl:0=[${MULTILIB_USEDEP}] )
  39         dmabuf? ( x11-libs/libdrm[${MULTILIB_USEDEP}] )
  40 "
  41 DEPEND="${RDEPEND}
  42         virtual/pkgconfig
  43         doc? ( app-doc/doxygen )
  44         test? ( >=dev-cpp/gtest-1.7 )
  45 "
  46
  47 src_prepare() {
  48         sed -i -e 's/-Werror//' configure.ac || die
  49         eautoreconf
  50 }
  51
  52 multilib_src_configure() {
  53         append-cppflags -I"${S}/"
  54         ECONF_SOURCE="${S}" econf \
  55                 $(use_enable debug) \
  56                 $(use_enable egl) \
  57                 $(use_enable v4l v4l2) \
  58                 $(use_enable v4l v4l2-ops) \
  59                 $(use_enable X x11) \
  60                 $(use_enable dmabuf) \
  61                 $(use_enable md5) \
  62                 $(use_enable wayland) \
  63                 $(use_enable test gtest) \
  64                 $(multilib_native_use_enable doc docs) \
  65                 --enable-h265dec \
  66                 --enable-vc1dec \
  67                 --enable-h264dec \
  68                 --enable-jpegdec \
  69                 --enable-mpeg2dec \
  70                 --enable-vp8dec \
  71                 --enable-vp9dec \
  72                 --enable-h265enc \
  73                 --enable-h264enc \
  74                 --enable-jpegenc \
  75                 --enable-vp8enc \
  76                 --enable-vp9enc
  77 }
  78
  79 multilib_src_compile() {
  80         emake
  81         multilib_is_native_abi && use doc && emake -C doc
  82 }
  83
  84 multilib_src_install() {
  85         emake DESTDIR="${D}" install
  86         multilib_is_native_abi && use doc && dohtml -r doc/html/*
  87 }
  88
  89 src_install() {
  90         multilib-minimal_src_install
  91         find "${ED}" -name '*.la' -delete
  92 }