media-libs/libsndfile/libsndfile-1.0.29_pre2_p20191024.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 PYTHON_COMPAT=( python{2_7,3_5,3_6,3_7} pypy{,3} )
   7
   8 inherit autotools python-any-r1 multilib-minimal
   9
  10 MY_COMMIT="97a361afc24202b16489d8c06910277c06b18b53"
  11
  12 SRC_URI="https://github.com/erikd/libsndfile/archive/${MY_COMMIT}.tar.gz -> ${P}.tar.gz"
  13 KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
  14 DESCRIPTION="C library for reading and writing files containing sampled sound"
  15 HOMEPAGE="http://www.mega-nerd.com/libsndfile"
  16
  17 LICENSE="LGPL-2.1"
  18 SLOT="0"
  19 IUSE="alsa minimal sqlite static-libs test"
  20
  21 RDEPEND="
  22         !minimal? (
  23                 >=media-libs/flac-1.2.1-r5:=[${MULTILIB_USEDEP}]
  24                 >=media-libs/libogg-1.3.0:=[${MULTILIB_USEDEP}]
  25                 >=media-libs/libvorbis-1.3.3-r1:=[${MULTILIB_USEDEP}]
  26                 >=media-libs/opus-1.1:=[${MULTILIB_USEDEP}]
  27         )
  28         alsa? ( media-libs/alsa-lib:= )
  29         sqlite? ( >=dev-db/sqlite-3.2 )"
  30 DEPEND="${RDEPEND}"
  31 BDEPEND="
  32         virtual/pkgconfig
  33         ${PYTHON_DEPS}
  34         sys-devel/autogen
  35         "
  36
  37 S="${WORKDIR}/${PN}-${MY_COMMIT}"
  38
  39 pkg_setup() {
  40         python-any-r1_pkg_setup
  41 }
  42
  43 src_prepare() {
  44         default
  45
  46         eautoreconf
  47 }
  48
  49 multilib_src_configure() {
  50         ECONF_SOURCE="${S}" econf \
  51                 --disable-octave \
  52                 $(use_enable static-libs static) \
  53                 $(use_enable !minimal external-libs) \
  54                 $(multilib_native_enable full-suite) \
  55                 $(multilib_native_use_enable alsa) \
  56                 $(multilib_native_use_enable sqlite) \
  57                 PYTHON="${EPYTHON}"
  58 }
  59
  60 multilib_src_install_all() {
  61         einstalldocs
  62
  63         # package provides .pc files
  64         find "${D}" -name '*.la' -delete || die
  65 }