media-libs/libsndfile/libsndfile-1.0.28-r2.ebuild

   1 # Copyright 1999-2018 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6} pypy{,3} )
   7
   8 inherit python-any-r1 multilib-minimal
   9
  10 MY_P=${P/_pre/pre}
  11
  12 DESCRIPTION="C library for reading and writing files containing sampled sound"
  13 HOMEPAGE="http://www.mega-nerd.com/libsndfile"
  14 if [[ ${MY_P} == ${P} ]]; then
  15         SRC_URI="http://www.mega-nerd.com/libsndfile/files/${P}.tar.gz"
  16 else
  17         SRC_URI="http://www.mega-nerd.com/tmp/${MY_P}b.tar.gz"
  18 fi
  19
  20 LICENSE="LGPL-2.1"
  21 SLOT="0"
  22 KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ppc ppc64 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
  23 IUSE="alsa minimal sqlite static-libs test"
  24
  25 RDEPEND="
  26         !minimal? (
  27                 >=media-libs/flac-1.2.1-r5[${MULTILIB_USEDEP}]
  28                 >=media-libs/libogg-1.3.0[${MULTILIB_USEDEP}]
  29                 >=media-libs/libvorbis-1.3.3-r1[${MULTILIB_USEDEP}]
  30         )
  31         alsa? ( media-libs/alsa-lib )
  32         sqlite? ( >=dev-db/sqlite-3.2 )"
  33 DEPEND="${RDEPEND}"
  34 BDEPEND="
  35         virtual/pkgconfig
  36         test? ( ${PYTHON_DEPS} )"
  37
  38 S=${WORKDIR}/${MY_P}
  39
  40 PATCHES=(
  41         "${FILESDIR}"/${P}-arm-varargs-failure.patch
  42         "${FILESDIR}"/${P}-CVE-2017-12562.patch
  43 )
  44
  45 pkg_setup() {
  46         use test && python-any-r1_pkg_setup
  47 }
  48
  49 multilib_src_configure() {
  50         ECONF_SOURCE="${S}" econf \
  51                 --disable-octave \
  52                 --enable-gcc-pipe \
  53                 --enable-gcc-opt \
  54                 $(use_enable static-libs static) \
  55                 $(use_enable !minimal external-libs) \
  56                 $(multilib_native_enable full-suite) \
  57                 $(multilib_native_use_enable alsa) \
  58                 $(multilib_native_use_enable sqlite)
  59 }
  60
  61 multilib_src_install_all() {
  62         einstalldocs
  63
  64         # package provides .pc files
  65         find "${D}" -name '*.la' -delete || die
  66 }