media-libs/libpng/libpng-1.6.18.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6
   7 inherit eutils libtool multilib-minimal
   8
   9 DESCRIPTION="Portable Network Graphics library"
  10 HOMEPAGE="http://www.libpng.org/"
  11 SRC_URI="mirror://sourceforge/${PN}/${P}.tar.xz
  12         apng? ( mirror://sourceforge/apng/${P}-apng.patch.gz )"
  13
  14 LICENSE="libpng"
  15 SLOT="0/16"
  16 KEYWORDS="alpha amd64 arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc x86 ~ppc-aix ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~x64-freebsd ~x86-freebsd ~x86-interix ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris ~x86-winnt"
  17 IUSE="apng neon static-libs"
  18
  19 RDEPEND=">=sys-libs/zlib-1.2.8-r1:=[${MULTILIB_USEDEP}]
  20         abi_x86_32? ( !<=app-emulation/emul-linux-x86-baselibs-20130224-r1
  21                 !app-emulation/emul-linux-x86-baselibs[-abi_x86_32(-)] )"
  22 DEPEND="${RDEPEND}
  23         app-arch/xz-utils"
  24
  25 src_prepare() {
  26         if use apng; then
  27                 epatch "${WORKDIR}"/${PN}-*-apng.patch
  28                 # Don't execute symbols check with apng patch wrt #378111
  29                 sed -i -e '/^check/s:scripts/symbols.chk::' Makefile.in || die
  30         fi
  31         elibtoolize
  32 }
  33
  34 multilib_src_configure() {
  35         ECONF_SOURCE="${S}" econf \
  36                 $(use_enable static-libs static) \
  37                 --enable-arm-neon=$(usex neon)
  38 }
  39
  40 multilib_src_install_all() {
  41         dodoc ANNOUNCE CHANGES libpng-manual.txt README TODO
  42         prune_libtool_files --all
  43 }