media-libs/libpng/libpng-1.5.28.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 # this ebuild is only for the libpng15.so.15 SONAME for ABI compat
   7
   8 inherit eutils libtool multilib-minimal
   9
  10 DESCRIPTION="Portable Network Graphics library"
  11 HOMEPAGE="http://www.libpng.org/"
  12 SRC_URI="mirror://sourceforge/${PN}/${P}.tar.xz
  13         apng? ( mirror://sourceforge/apng/${P}-apng.patch.gz )"
  14
  15 LICENSE="libpng"
  16 SLOT="1.5"
  17 KEYWORDS="~alpha amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc x86 ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris ~x86-winnt"
  18 IUSE="apng neon"
  19
  20 RDEPEND="sys-libs/zlib:=[${MULTILIB_USEDEP}]
  21         !=media-libs/libpng-1.5*:0
  22         abi_x86_32? ( !<=app-emulation/emul-linux-x86-baselibs-20140406-r4
  23                 !app-emulation/emul-linux-x86-baselibs[-abi_x86_32(-)] )"
  24 DEPEND="${RDEPEND}
  25         app-arch/xz-utils"
  26
  27 DOCS=""
  28
  29 pkg_setup() {
  30         local _preserved_lib=${EROOT}/usr/$(get_libdir)/libpng15.so.15
  31         [[ -e ${_preserved_lib} ]] && rm -f "${_preserved_lib}"
  32 }
  33
  34 src_prepare() {
  35         default
  36         if use apng; then
  37                 # fix windows path in patch file. Please check for each release if this can be removed again.
  38                 sed 's@scripts\\symbols.def@scripts/symbols.def@' \
  39                         -i "${WORKDIR}"/${PN}-*-apng.patch || die
  40                 eapply -p0 "${WORKDIR}"/${PN}-*-apng.patch
  41                 # Don't execute symbols check with apng patch wrt #378111
  42                 sed -i -e '/^check/s:scripts/symbols.chk::' Makefile.in || die
  43         fi
  44         elibtoolize
  45 }
  46
  47 multilib_src_configure() {
  48         ECONF_SOURCE="${S}" \
  49         econf \
  50                 --disable-static \
  51                 --enable-arm-neon=$(usex neon)
  52 }
  53
  54 multilib_src_compile() {
  55         emake libpng15.la
  56 }
  57
  58 multilib_src_install() {
  59         newlib.so .libs/libpng15.so.15.* libpng15.so.15
  60 }