media-libs/libopenglrecorder/libopenglrecorder-0.1.0.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit cmake-multilib
   7
   8 DESCRIPTION="Library for asynchronous OpenGL recording with audio"
   9 HOMEPAGE="https://github.com/Benau/libopenglrecorder"
  10 SRC_URI="${HOMEPAGE}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
  11
  12 LICENSE="BSD"
  13 SLOT="0"
  14 KEYWORDS="~amd64 ~x86"
  15 IUSE="openh264 sound vpx"
  16
  17 RDEPEND="media-libs/libjpeg-turbo[${MULTILIB_USEDEP}]
  18         openh264? ( media-libs/openh264[${MULTILIB_USEDEP}] )
  19         sound? (
  20                 media-libs/libvorbis[${MULTILIB_USEDEP}]
  21                 media-sound/pulseaudio[${MULTILIB_USEDEP}]
  22         )
  23         vpx? ( media-libs/libvpx:0=[${MULTILIB_USEDEP}] )"
  24
  25 DEPEND="${RDEPEND}
  26         virtual/pkgconfig"
  27
  28 DOCS=(
  29         CHANGELOG.md
  30         README.md
  31         USAGE.md
  32 )
  33
  34 multilib_src_configure() {
  35         local mycmakeargs=(
  36                         -DBUILD_PULSE_WO_DL=ON
  37                         -DBUILD_SHARED_LIBS=ON
  38                         -DSTATIC_RUNTIME_LIBS=OFF
  39                         -DBUILD_WITH_H264=$(usex openh264)
  40                         -DBUILD_RECORDER_WITH_SOUND=$(usex sound)
  41                         -DBUILD_WITH_VPX=$(usex vpx)
  42         )
  43         cmake-utils_src_configure
  44 }