media-libs/libnjb/libnjb-2.2.7.ebuild

   1 # Copyright 1999-2018 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit libtool udev
   7
   8 DESCRIPTION="Library for communicating with the Creative Nomad JukeBox digital audio player"
   9 HOMEPAGE="http://libnjb.sourceforge.net"
  10 SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
  11
  12 LICENSE="BSD"
  13 SLOT="0"
  14 KEYWORDS="amd64 ppc ppc64 x86"
  15 IUSE="doc static-libs"
  16
  17 RDEPEND="virtual/libusb:0"
  18 DEPEND="${RDEPEND}
  19         doc? ( app-doc/doxygen )"
  20
  21 PATCHES=( "${FILESDIR}"/${P}-exclude-samples.patch )
  22
  23 src_prepare() {
  24         default
  25         elibtoolize
  26 }
  27
  28 src_configure() {
  29         use doc || export ac_cv_prog_HAVE_DOXYGEN=false
  30
  31         econf \
  32                 $(use_enable static-libs static)
  33 }
  34
  35 src_install() {
  36         default
  37
  38         udev_newrules "${FILESDIR}"/${PN}.rules 80-${PN}.rules
  39
  40         # package provides .pc files
  41         find "${D}" -name '*.la' -delete || die
  42 }