media-libs/libfreehand/libfreehand-9999.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit flag-o-matic
   7
   8 if [[ ${PV} = *9999 ]]; then
   9         EGIT_REPO_URI="https://anongit.freedesktop.org/git/libreoffice/libfreehand.git"
  10         inherit autotools git-r3
  11 else
  12         SRC_URI="https://dev-www.libreoffice.org/src/libfreehand/${P}.tar.xz"
  13         KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~sparc ~x86"
  14 fi
  15 DESCRIPTION="Library for import of FreeHand drawings"
  16 HOMEPAGE="https://wiki.documentfoundation.org/DLP/Libraries/libfreehand"
  17
  18 LICENSE="MPL-2.0"
  19 SLOT="0"
  20 IUSE="doc static-libs test"
  21 RESTRICT="!test? ( test )"
  22
  23 BDEPEND="
  24         virtual/pkgconfig
  25         doc? ( app-doc/doxygen )
  26 "
  27 RDEPEND="
  28         dev-libs/librevenge
  29         sys-libs/zlib
  30 "
  31 DEPEND="${RDEPEND}
  32         dev-libs/boost
  33         dev-libs/icu
  34         dev-util/gperf
  35         media-libs/lcms
  36         sys-devel/libtool
  37         test? ( dev-util/cppunit )
  38 "
  39
  40 src_prepare() {
  41         default
  42         [[ -d m4 ]] || mkdir "m4"
  43         [[ ${PV} == *9999 ]] && eautoreconf
  44 }
  45
  46 src_configure() {
  47         # bug 619762
  48         append-cxxflags -std=c++14
  49
  50         local myeconfargs=(
  51                 --disable-werror
  52                 $(use_with doc docs)
  53                 $(use_enable static-libs static)
  54                 $(use_enable test tests)
  55         )
  56         econf "${myeconfargs[@]}"
  57 }
  58
  59 src_install() {
  60         default
  61         find "${D}" -name '*.la' -type f -delete || die
  62 }