media-libs/libfreehand/libfreehand-0.1.2.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit flag-o-matic
   7
   8 EGIT_REPO_URI="https://anongit.freedesktop.org/git/libreoffice/libfreehand.git"
   9 [[ ${PV} == 9999 ]] && inherit autotools git-r3
  10
  11 DESCRIPTION="Library for import of FreeHand drawings"
  12 HOMEPAGE="https://wiki.documentfoundation.org/DLP/Libraries/libfreehand"
  13 [[ ${PV} == 9999 ]] || SRC_URI="https://dev-www.libreoffice.org/src/libfreehand/${P}.tar.xz"
  14
  15 LICENSE="MPL-2.0"
  16 SLOT="0"
  17 [[ ${PV} == 9999 ]] || \
  18 KEYWORDS="amd64 ~arm arm64 ~hppa ppc ppc64 ~sparc x86"
  19 IUSE="doc static-libs test"
  20 RESTRICT="!test? ( test )"
  21
  22 RDEPEND="
  23         dev-libs/librevenge
  24         sys-libs/zlib
  25 "
  26 DEPEND="${RDEPEND}
  27         dev-libs/boost
  28         dev-libs/icu
  29         dev-util/gperf
  30         media-libs/lcms
  31         sys-devel/libtool
  32         virtual/pkgconfig
  33         doc? ( app-doc/doxygen )
  34         test? ( dev-util/cppunit )
  35 "
  36
  37 PATCHES=( "${FILESDIR}/${P}-icu-65.patch" )
  38
  39 src_prepare() {
  40         default
  41         [[ -d m4 ]] || mkdir "m4"
  42         [[ ${PV} == 9999 ]] && eautoreconf
  43 }
  44
  45 src_configure() {
  46         # bug 619762
  47         append-cxxflags -std=c++14
  48
  49         econf \
  50                 --disable-werror \
  51                 $(use_with doc docs) \
  52                 $(use_enable static-libs static) \
  53                 $(use_enable test tests)
  54 }
  55
  56 src_install() {
  57         default
  58         find "${D}" -name '*.la' -delete || die
  59 }