media-libs/libexif/libexif-0.6.21-r3.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit libtool multilib-minimal
   7
   8 DESCRIPTION="Library for parsing, editing, and saving EXIF data"
   9 HOMEPAGE="https://libexif.github.io/"
  10 SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"
  11
  12 LICENSE="LGPL-2.1"
  13 SLOT="0"
  14 KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~mips ppc ppc64 ~s390 sparc x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~x64-solaris ~x86-solaris"
  15 IUSE="doc nls static-libs"
  16
  17 RDEPEND="nls? ( virtual/libintl )"
  18 DEPEND="${RDEPEND}"
  19 BDEPEND="
  20         virtual/pkgconfig
  21         doc? ( app-doc/doxygen )
  22         nls? ( sys-devel/gettext )"
  23
  24 PATCHES=(
  25         "${FILESDIR}"/${PN}-0.6.13-pkgconfig.patch
  26         "${FILESDIR}"/${P}-fix-C89-compatibility-issue.patch
  27         "${FILESDIR}"/${P}-CVE-2017-7544.patch
  28         "${FILESDIR}"/${P}-CVE-2018-20030.patch
  29 )
  30
  31 src_prepare() {
  32         default
  33         sed -i -e '/FLAGS=/s:-g::' configure || die #390249
  34         elibtoolize # For *-bsd
  35 }
  36
  37 multilib_src_configure() {
  38         ECONF_SOURCE=${S} econf \
  39                 $(use_enable doc docs) \
  40                 $(use_enable nls) \
  41                 $(use_enable static-libs static) \
  42                 --with-doc-dir="${EPREFIX}"/usr/share/doc/${PF}
  43 }
  44
  45 multilib_src_install() {
  46         emake DESTDIR="${D}" install
  47 }
  48
  49 multilib_src_install_all() {
  50         find "${D}" -name '*.la' -delete || die
  51         rm -f "${ED}"/usr/share/doc/${PF}/{ABOUT-NLS,COPYING} || die
  52 }