media-libs/libdvdread/libdvdread-9999.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit autotools multilib-minimal
   7
   8 DESCRIPTION="Library for DVD navigation tools"
   9 HOMEPAGE="https://www.videolan.org/developers/libdvdnav.html"
  10 if [[ ${PV} = 9999 ]]; then
  11         inherit git-r3
  12         EGIT_REPO_URI="https://code.videolan.org/videolan/libdvdread.git"
  13 else
  14         SRC_URI="https://downloads.videolan.org/pub/videolan/libdvdread/${PV}/${P}.tar.bz2"
  15         KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x86-solaris"
  16 fi
  17
  18 LICENSE="GPL-2"
  19 SLOT="0/8" # libdvdread.so.VERSION
  20 IUSE="+css static-libs"
  21
  22 RDEPEND="css? ( >=media-libs/libdvdcss-1.3.0[${MULTILIB_USEDEP}] )"
  23 DEPEND="${RDEPEND}"
  24 BDEPEND="virtual/pkgconfig"
  25
  26 DOCS=( AUTHORS ChangeLog NEWS TODO README )
  27
  28 src_prepare() {
  29         default
  30         eautoreconf
  31 }
  32
  33 multilib_src_configure() {
  34         local myeconfargs=(
  35                 --enable-shared
  36                 $(use_enable static-libs static)
  37                 $(use_with css libdvdcss)
  38         )
  39         ECONF_SOURCE="${S}" econf "${myeconfargs[@]}"
  40 }
  41
  42 multilib_src_install_all() {
  43         find "${ED}" -type f -name "*.la" -delete || die
  44 }