media-libs/libchamplain/libchamplain-0.12.20.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5 VALA_USE_DEPEND="vapigen"
   6
   7 inherit gnome.org meson vala xdg
   8
   9 DESCRIPTION="Clutter based world map renderer"
  10 HOMEPAGE="https://wiki.gnome.org/Projects/libchamplain"
  11
  12 SLOT="0.12"
  13 LICENSE="LGPL-2.1+"
  14 KEYWORDS="~alpha amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc x86"
  15
  16 IUSE="+gtk gtk-doc +introspection vala"
  17 REQUIRED_USE="
  18         vala? ( introspection )
  19         gtk-doc? ( gtk )
  20 " # gtk-doc build gets disabled in meson if gtk widgetry is disabled (no separate libchamplain-gtk gtk-docs anymore)
  21
  22 RDEPEND="
  23         >=dev-libs/glib-2.38:2
  24         >=x11-libs/gtk+-3.0:3
  25         >=media-libs/clutter-1.24:1.0[introspection?]
  26         gtk? (
  27                 x11-libs/gtk+:3[introspection?]
  28                 media-libs/clutter-gtk:1.0 )
  29         >=x11-libs/cairo-1.4
  30         dev-db/sqlite:3
  31         >=net-libs/libsoup-2.42:2.4
  32         introspection? ( >=dev-libs/gobject-introspection-1.54:= )
  33         media-libs/cogl:=
  34 "
  35 DEPEND="${RDEPEND}"
  36 BDEPEND="
  37         dev-util/glib-utils
  38         >=dev-util/meson-0.49.0
  39         virtual/pkgconfig
  40         gtk-doc? ( >=dev-util/gtk-doc-1.15 )
  41         vala? ( $(vala_depend) )
  42 "
  43
  44 src_prepare() {
  45         xdg_src_prepare
  46         use vala && vala_src_prepare
  47 }
  48
  49 src_configure() {
  50         local emesonargs=(
  51                 -Dmemphis=false # TODO: What's the state of this vector renderer?
  52                 $(meson_use introspection)
  53                 $(meson_use vala vapi)
  54                 $(meson_use gtk widgetry)
  55                 $(meson_use gtk-doc gtk_doc)
  56                 -Ddemos=false # only built, not installed
  57         )
  58         meson_src_configure
  59 }