media-libs/libaacplus/libaacplus-2.0.2-r2.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6
   7 inherit autotools eutils multilib-minimal
   8
   9 # This file cannot be mirrored.
  10 # See the notes at http://tipok.org.ua/node/17
  11 # The .tar.gz, ie the wrapper library, is lgpl though.
  12 TGPPDIST=26410-800.zip
  13
  14 DESCRIPTION="HE-AAC+ v2 library, based on the reference implementation"
  15 HOMEPAGE="http://tipok.org.ua/node/17"
  16 SRC_URI="
  17         https://dev.gentoo.org/~aballier/${P}.tar.gz
  18         http://tipok.ath.cx/downloads/media/aac+/libaacplus/${P}.tar.gz
  19         http://217.20.164.161/~tipok/aacplus/${P}.tar.gz
  20         http://www.3gpp.org/ftp/Specs/archive/26_series/26.410/${TGPPDIST}"
  21
  22 LICENSE="LGPL-2.1"
  23 SLOT="0"
  24 KEYWORDS="amd64 hppa ppc ppc64 x86 ~amd64-fbsd ~x86-fbsd"
  25 IUSE="fftw static-libs"
  26 RESTRICT="bindist mirror"
  27
  28 RDEPEND="
  29         !media-sound/aacplusenc
  30         fftw? ( >=sci-libs/fftw-3.3.3-r2:3.0[${MULTILIB_USEDEP}] )"
  31 DEPEND="${RDEPEND}
  32         app-arch/unzip
  33         virtual/pkgconfig"
  34
  35 src_unpack() {
  36         unpack ${P}.tar.gz
  37 }
  38
  39 src_prepare() {
  40         sed \
  41                 -e 's/AM_CONFIG_HEADER/AC_CONFIG_HEADERS/g' \
  42                 -i configure.ac || die
  43         eautoreconf
  44         cp "${DISTDIR}/${TGPPDIST}" src/ || die
  45         multilib_copy_sources
  46 }
  47
  48 multilib_src_configure() {
  49         econf \
  50                 $(use_with fftw fftw3) \
  51                 $(use_enable static-libs static)
  52 }
  53
  54 multilib_src_compile() {
  55         emake -j1
  56 }
  57
  58 multilib_src_install_all() {
  59         prune_libtool_files --all
  60         einstalldocs
  61 }