media-libs/leptonica/leptonica-1.74.4.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit eutils ltprune multilib-minimal
   7
   8 DESCRIPTION="C library for image processing and analysis"
   9 HOMEPAGE="http://www.leptonica.org/"
  10 SRC_URI="https://github.com/DanBloomberg/${PN}/releases/download/${PV}/${P}.tar.gz"
  11 LICENSE="Apache-2.0"
  12 SLOT="0/5"
  13 KEYWORDS="~alpha amd64 arm arm64 ~mips ppc ppc64 ~sparc x86 ~ppc-macos"
  14 IUSE="gif jpeg jpeg2k png static-libs test tiff utils webp zlib"
  15 RESTRICT="!test? ( test )"
  16
  17 # N.B. Tests need some features enabled:
  18 REQUIRED_USE="test? ( jpeg png tiff zlib )"
  19
  20 DEPEND="gif? ( media-libs/giflib:=[${MULTILIB_USEDEP}] )
  21         jpeg? ( virtual/jpeg:0=[${MULTILIB_USEDEP}] )
  22         jpeg2k? ( media-libs/openjpeg:2=[${MULTILIB_USEDEP}] )
  23         png? ( media-libs/libpng:0=[${MULTILIB_USEDEP}]
  24                    sys-libs/zlib:=[${MULTILIB_USEDEP}] )
  25         tiff? ( media-libs/tiff:0=[${MULTILIB_USEDEP}] )
  26         webp? ( media-libs/libwebp:=[${MULTILIB_USEDEP}] )
  27         zlib? ( sys-libs/zlib:=[${MULTILIB_USEDEP}] )"
  28 RDEPEND="${DEPEND}"
  29
  30 PATCHES=( "${FILESDIR}"/baseline_reg.patch )
  31 ECONF_SOURCE="${S}"
  32 DOCS=( README version-notes )
  33
  34 src_prepare() {
  35         default
  36
  37         # unhtmlize docs
  38         local X
  39         for X in ${DOCS[@]}; do
  40                 awk '/<\/pre>/{s--} {if (s) print $0} /<pre>/{s++}' \
  41                         "${X}.html" > "${X}" || die 'awk failed'
  42                 rm -f -- "${X}.html"
  43         done
  44 }
  45
  46 multilib_src_configure() {
  47         econf \
  48                 --enable-shared \
  49                 $(use_with gif giflib) \
  50                 $(use_with jpeg) \
  51                 $(use_with jpeg2k libopenjpeg) \
  52                 $(use_with png libpng) \
  53                 $(use_with tiff libtiff) \
  54                 $(use_with webp libwebp) \
  55                 $(use_with zlib) \
  56                 $(use_enable static-libs static) \
  57                 $(multilib_native_use_enable utils programs)
  58 }
  59
  60 src_install() {
  61         multilib-minimal_src_install
  62         prune_libtool_files
  63 }