media-libs/lcms/lcms-2.9.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit libtool multilib-minimal
   7
   8 DESCRIPTION="A lightweight, speed optimized color management engine"
   9 HOMEPAGE="http://www.littlecms.com/"
  10 SRC_URI="mirror://sourceforge/${PN}/lcms2-${PV}.tar.gz"
  11
  12 LICENSE="MIT"
  13 SLOT="2"
  14 KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~m68k ~mips ppc ppc64 s390 sparc x86 ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
  15 IUSE="doc jpeg static-libs test +threads tiff"
  16 RESTRICT="!test? ( test )"
  17
  18 RDEPEND="
  19         jpeg? ( >=virtual/jpeg-0-r2:0[${MULTILIB_USEDEP}] )
  20         tiff? ( >=media-libs/tiff-4.0.3-r6:0=[${MULTILIB_USEDEP}] )
  21 "
  22 DEPEND="${RDEPEND}"
  23
  24 S="${WORKDIR}/lcms2-${PV}"
  25
  26 PATCHES=("${FILESDIR}"/${P}-BE-test.patch)
  27
  28 src_prepare() {
  29         default
  30         elibtoolize  # for Prefix/Solaris
  31 }
  32
  33 multilib_src_configure() {
  34         local myeconfargs=(
  35                 $(use_with jpeg)
  36                 $(use_enable static-libs static)
  37                 $(use_with threads)
  38                 $(use_with tiff)
  39                 --without-zlib
  40         )
  41         ECONF_SOURCE="${S}" \
  42         econf ${myeconfargs[@]}
  43 }
  44
  45 multilib_src_install_all() {
  46         find "${ED}" -name "*.la" -delete || die
  47
  48         if use doc; then
  49                 docinto pdf
  50                 dodoc doc/*.pdf
  51         fi
  52 }