media-libs/glew/glew-1.11.0.ebuild

   1 # Copyright 1999-2014 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6 inherit multilib multilib-minimal toolchain-funcs versionator
   7
   8 DESCRIPTION="The OpenGL Extension Wrangler Library"
   9 HOMEPAGE="http://glew.sourceforge.net/"
  10 SRC_URI="mirror://sourceforge/${PN}/${P}.tgz"
  11
  12 LICENSE="BSD MIT"
  13 SLOT="0/$(get_version_component_range 1-2)"
  14 KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x86-freebsd ~amd64-linux ~ia64-linux ~x86-linux ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
  15 IUSE="doc static-libs"
  16
  17 RDEPEND=">=virtual/glu-9.0-r1[${MULTILIB_USEDEP}]
  18         >=virtual/opengl-7.0-r1[${MULTILIB_USEDEP}]
  19         >=x11-libs/libX11-1.6.2[${MULTILIB_USEDEP}]
  20         >=x11-libs/libXext-1.3.2[${MULTILIB_USEDEP}]
  21         >=x11-libs/libXi-1.7.2[${MULTILIB_USEDEP}]
  22         >=x11-libs/libXmu-1.1.1-r1[${MULTILIB_USEDEP}]
  23         abi_x86_32? ( !app-emulation/emul-linux-x86-opengl[-abi_x86_32(-)] )"
  24 DEPEND=${RDEPEND}
  25
  26 src_prepare() {
  27         sed -i \
  28                 -e '/INSTALL/s:-s::' \
  29                 -e '/$(CC) $(CFLAGS) -o/s:$(CFLAGS):$(CFLAGS) $(LDFLAGS):' \
  30                 -e '/^.PHONY: .*\.pc$/d' \
  31                 Makefile || die
  32
  33         if ! use static-libs ; then
  34                 sed -i \
  35                         -e '/glew.lib:/s|lib/$(LIB.STATIC) ||' \
  36                         -e '/glew.lib.mx:/s|lib/$(LIB.STATIC.MX) ||' \
  37                         -e '/INSTALL.*LIB.STATIC/d' \
  38                         Makefile || die
  39         fi
  40
  41         # don't do stupid Solaris specific stuff that won't work in Prefix
  42         cp config/Makefile.linux config/Makefile.solaris || die
  43         # and let freebsd be built as on linux too
  44         cp config/Makefile.linux config/Makefile.freebsd || die
  45
  46         multilib_copy_sources
  47 }
  48
  49 set_opts() {
  50         myglewopts=(
  51                 AR="$(tc-getAR)"
  52                 STRIP=true
  53                 CC="$(tc-getCC)"
  54                 LD="$(tc-getCC) ${LDFLAGS}"
  55                 M_ARCH=""
  56                 LDFLAGS.EXTRA=""
  57                 POPT="${CFLAGS}"
  58         )
  59
  60         # support MinGW targets (bug #523444)
  61         [[ ${CHOST} == *-mingw* ]] && myglewopts+=( SYSTEM=mingw )
  62 }
  63
  64 multilib_src_compile() {
  65         set_opts
  66         emake GLEW_DEST="${EPREFIX}/usr" LIBDIR="${EPREFIX}/usr/$(get_libdir)" "${myglewopts[@]}"
  67 }
  68
  69 multilib_src_install() {
  70         set_opts
  71         emake \
  72                 GLEW_DEST="${ED}/usr" \
  73                 LIBDIR="${ED}/usr/$(get_libdir)" \
  74                 "${myglewopts[@]}" \
  75                 install.all
  76
  77         dodoc TODO.txt
  78         use doc && dohtml doc/*
  79 }