media-libs/gd/gd-2.2.5-r1.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit libtool multilib-minimal
   7
   8 DESCRIPTION="Graphics library for fast image creation"
   9 HOMEPAGE="https://libgd.org/ https://www.boutell.com/gd/"
  10 SRC_URI="https://github.com/libgd/libgd/releases/download/${P}/lib${P}.tar.xz"
  11
  12 LICENSE="gd IJG HPND BSD"
  13 SLOT="2/3"
  14 KEYWORDS="alpha amd64 arm arm64 hppa ia64 ~m68k ~mips ppc ppc64 s390 ~sh sparc x86 ~ppc-aix ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
  15 IUSE="fontconfig jpeg png static-libs tiff truetype webp xpm zlib"
  16
  17 # fontconfig has prefixed font paths, details see bug #518970
  18 REQUIRED_USE="prefix? ( fontconfig )"
  19
  20 RDEPEND="fontconfig? ( >=media-libs/fontconfig-2.10.92[${MULTILIB_USEDEP}] )
  21         jpeg? ( >=virtual/jpeg-0-r2:0=[${MULTILIB_USEDEP}] )
  22         png? ( >=media-libs/libpng-1.6.10:0=[${MULTILIB_USEDEP}] )
  23         tiff? ( media-libs/tiff:0[${MULTILIB_USEDEP}] )
  24         truetype? ( >=media-libs/freetype-2.5.0.1[${MULTILIB_USEDEP}] )
  25         webp? ( media-libs/libwebp:=[${MULTILIB_USEDEP}] )
  26         xpm? ( >=x11-libs/libXpm-3.5.10-r1[${MULTILIB_USEDEP}] >=x11-libs/libXt-1.1.4[${MULTILIB_USEDEP}] )
  27         zlib? ( >=sys-libs/zlib-1.2.8-r1[${MULTILIB_USEDEP}] )"
  28 DEPEND="${RDEPEND}
  29         >=virtual/pkgconfig-0-r1[${MULTILIB_USEDEP}]"
  30
  31 S="${WORKDIR}/lib${P}"
  32
  33 PATCHES=( "${FILESDIR}/${P}-CVE-2018-1000222.patch" )
  34
  35 src_prepare() {
  36         default
  37         elibtoolize  # for shared library on Solaris
  38 }
  39
  40 multilib_src_configure() {
  41         # we aren't actually {en,dis}abling X here ... the configure
  42         # script uses it just to add explicit -I/-L paths which we
  43         # don't care about on Gentoo systems.
  44         local myeconfargs=(
  45                 --disable-werror
  46                 --without-x
  47                 --without-liq
  48                 $(use_enable static-libs static)
  49                 $(use_with fontconfig)
  50                 $(use_with png)
  51                 $(use_with tiff)
  52                 $(use_with truetype freetype)
  53                 $(use_with jpeg)
  54                 $(use_with webp)
  55                 $(use_with xpm)
  56                 $(use_with zlib)
  57         )
  58         ECONF_SOURCE="${S}" econf "${myeconfargs[@]}"
  59 }
  60
  61 multilib_src_install_all() {
  62         dodoc README.md
  63         find "${D}" -name '*.la' -delete || die
  64 }