media-libs/gd/gd-2.2.4.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI="6"
   6
   7 inherit libtool multilib-minimal
   8
   9 DESCRIPTION="A graphics library for fast image creation"
  10 HOMEPAGE="http://libgd.org/ http://www.boutell.com/gd/"
  11 SRC_URI="https://github.com/libgd/libgd/releases/download/${P}/lib${P}.tar.xz"
  12
  13 LICENSE="gd IJG HPND BSD"
  14 SLOT="2/3"
  15 KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
  16 IUSE="fontconfig jpeg png static-libs tiff truetype webp xpm zlib"
  17
  18 # fontconfig has prefixed font paths, details see bug #518970
  19 REQUIRED_USE="prefix? ( fontconfig )"
  20
  21 RDEPEND="fontconfig? ( >=media-libs/fontconfig-2.10.92[${MULTILIB_USEDEP}] )
  22         jpeg? ( >=virtual/jpeg-0-r2:0=[${MULTILIB_USEDEP}] )
  23         png? ( >=media-libs/libpng-1.6.10:0=[${MULTILIB_USEDEP}] )
  24         tiff? ( media-libs/tiff:0[${MULTILIB_USEDEP}] )
  25         truetype? ( >=media-libs/freetype-2.5.0.1[${MULTILIB_USEDEP}] )
  26         webp? ( media-libs/libwebp[${MULTILIB_USEDEP}] )
  27         xpm? ( >=x11-libs/libXpm-3.5.10-r1[${MULTILIB_USEDEP}] >=x11-libs/libXt-1.1.4[${MULTILIB_USEDEP}] )
  28         zlib? ( >=sys-libs/zlib-1.2.8-r1[${MULTILIB_USEDEP}] )"
  29 DEPEND="${RDEPEND}
  30         >=virtual/pkgconfig-0-r1[${MULTILIB_USEDEP}]"
  31
  32 S="${WORKDIR}/lib${P}"
  33
  34 src_prepare() {
  35         default
  36         elibtoolize  # for shared library on Solaris
  37 }
  38
  39 multilib_src_configure() {
  40         # we aren't actually {en,dis}abling X here ... the configure
  41         # script uses it just to add explicit -I/-L paths which we
  42         # don't care about on Gentoo systems.
  43         ECONF_SOURCE=${S} \
  44         econf \
  45                 --disable-werror \
  46                 --without-x \
  47                 --without-liq \
  48                 $(use_enable static-libs static) \
  49                 $(use_with fontconfig) \
  50                 $(use_with png) \
  51                 $(use_with tiff) \
  52                 $(use_with truetype freetype) \
  53                 $(use_with jpeg) \
  54                 $(use_with webp) \
  55                 $(use_with xpm) \
  56                 $(use_with zlib)
  57 }
  58
  59 multilib_src_install_all() {
  60         dodoc README.md
  61         find "${ED}" \( -name "*.a" -o -name "*.la" \) -delete || die
  62 }