media-libs/devil/devil-1.7.8-r2.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit autotools
   7
   8 MY_P=DevIL-${PV}
   9
  10 DESCRIPTION="DevIL image library"
  11 HOMEPAGE="http://openil.sourceforge.net/"
  12 SRC_URI="mirror://sourceforge/openil/${MY_P}.tar.gz"
  13
  14 LICENSE="LGPL-2.1"
  15 SLOT="0"
  16 KEYWORDS="amd64 ~arm arm64 ~hppa ~mips ppc ppc64 x86"
  17 IUSE="allegro cpu_flags_x86_sse cpu_flags_x86_sse2 cpu_flags_x86_sse3 gif glut jpeg mng nvtt openexr opengl png sdl static-libs tiff X xpm"
  18
  19 RDEPEND="
  20         allegro? ( media-libs/allegro:0 )
  21         gif? ( media-libs/giflib:= )
  22         glut? ( media-libs/freeglut )
  23         jpeg? ( virtual/jpeg:0 )
  24         mng? ( media-libs/libmng:= )
  25         nvtt? ( media-gfx/nvidia-texture-tools )
  26         openexr? ( media-libs/openexr:= )
  27         opengl? ( virtual/opengl
  28                 virtual/glu )
  29         png? ( media-libs/libpng:0= )
  30         sdl? ( media-libs/libsdl )
  31         tiff? ( media-libs/tiff:0 )
  32         X? ( x11-libs/libXext
  33                  x11-libs/libX11
  34                  x11-libs/libXrender )
  35         xpm? ( x11-libs/libXpm )"
  36 DEPEND="${RDEPEND}
  37         virtual/pkgconfig
  38         X? ( x11-base/xorg-proto )"
  39
  40 PATCHES=(
  41         "${FILESDIR}/${P}"-CVE-2009-3994.patch
  42         "${FILESDIR}/${P}"-libpng14.patch
  43         "${FILESDIR}/${P}"-nvtt-glut.patch
  44         "${FILESDIR}/${P}"-ILUT.patch
  45         "${FILESDIR}/${P}"-restrict.patch
  46         "${FILESDIR}/${P}"-fix-test.patch
  47         "${FILESDIR}/${P}"-jasper-remove-uchar.patch
  48 )
  49
  50 src_prepare() {
  51         default
  52         eautoreconf
  53 }
  54
  55 src_configure() {
  56         econf \
  57                 $(use_enable static-libs static) \
  58                 --disable-lcms \
  59                 --enable-ILU \
  60                 --enable-ILUT \
  61                 $(use_enable cpu_flags_x86_sse sse) \
  62                 $(use_enable cpu_flags_x86_sse2 sse2) \
  63                 $(use_enable cpu_flags_x86_sse3 sse3) \
  64                 $(use_enable openexr exr) \
  65                 $(use_enable gif) \
  66                 $(use_enable jpeg) \
  67                 --enable-jp2 \
  68                 $(use_enable mng) \
  69                 $(use_enable png) \
  70                 $(use_enable tiff) \
  71                 $(use_enable xpm) \
  72                 $(use_enable allegro) \
  73                 --disable-directx8 \
  74                 --disable-directx9 \
  75                 $(use_enable opengl) \
  76                 $(use_enable sdl) \
  77                 $(use_enable X x11) \
  78                 $(use_enable X shm) \
  79                 $(use_enable X render) \
  80                 $(use_enable glut) \
  81                 $(use_with X x) \
  82                 $(use_with nvtt)
  83 }
  84
  85 src_install() {
  86         default
  87
  88         # package provides .pc files
  89         find "${D}" -name '*.la' -delete || die
  90 }