media-libs/clutter/clutter-1.26.0.ebuild

   1 # Copyright 1999-2016 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 GNOME2_LA_PUNT="yes"
   6
   7 inherit gnome2 virtualx
   8
   9 HOMEPAGE="https://wiki.gnome.org/Projects/Clutter"
  10 DESCRIPTION="Clutter is a library for creating graphical user interfaces"
  11
  12 LICENSE="LGPL-2.1+ FDL-1.1+"
  13 SLOT="1.0"
  14
  15 IUSE="aqua debug doc egl gtk +introspection test wayland X"
  16 REQUIRED_USE="
  17         || ( aqua wayland X )
  18         wayland? ( egl )
  19 "
  20
  21 KEYWORDS="~alpha amd64 ~arm ~ia64 ~mips ~ppc ~ppc64 ~sparc x86"
  22
  23 # NOTE: glx flavour uses libdrm + >=mesa-7.3
  24 # >=libX11-1.3.1 needed for X Generic Event support
  25 # do not depend on tslib, it does not build and is disabled by default upstream
  26 RDEPEND="
  27         >=dev-libs/glib-2.44.0:2
  28         >=dev-libs/atk-2.5.3[introspection?]
  29         >=dev-libs/json-glib-0.12[introspection?]
  30         >=media-libs/cogl-1.21.2:1.0=[introspection?,pango,wayland?]
  31         >=x11-libs/cairo-1.14:=[aqua?,glib]
  32         >=x11-libs/pango-1.30[introspection?]
  33
  34         virtual/opengl
  35         x11-libs/libdrm:=
  36
  37         egl? (
  38                 >=dev-libs/libinput-0.19.0
  39                 media-libs/cogl[gles2,kms]
  40                 >=virtual/libgudev-136
  41                 x11-libs/libxkbcommon
  42         )
  43         gtk? ( >=x11-libs/gtk+-3.3.18:3[aqua?] )
  44         introspection? ( >=dev-libs/gobject-introspection-1.39:= )
  45         X? (
  46                 media-libs/fontconfig
  47                 >=x11-libs/libX11-1.3.1
  48                 x11-libs/libXext
  49                 x11-libs/libXdamage
  50                 x11-proto/inputproto
  51                 >=x11-libs/libXi-1.3
  52                 >=x11-libs/libXcomposite-0.4 )
  53         wayland? (
  54                 dev-libs/wayland
  55                 x11-libs/gdk-pixbuf:2 )
  56 "
  57 DEPEND="${RDEPEND}
  58         >=dev-util/gtk-doc-am-1.20
  59         >=sys-devel/gettext-0.17
  60         virtual/pkgconfig
  61         doc? (
  62                 >=dev-util/gtk-doc-1.20
  63                 >=app-text/docbook-sgml-utils-0.6.14[jadetex]
  64                 dev-libs/libxslt )
  65         test? ( x11-libs/gdk-pixbuf )
  66 "
  67
  68 src_prepare() {
  69         # We only need conformance tests, the rest are useless for us
  70         sed -e 's/^\(SUBDIRS =\).*/\1 accessibility conform/g' \
  71                 -i tests/Makefile.am || die "am tests sed failed"
  72         sed -e 's/^\(SUBDIRS =\)[^\]*/\1  accessibility conform/g' \
  73                 -i tests/Makefile.in || die "in tests sed failed"
  74
  75         gnome2_src_prepare
  76 }
  77
  78 src_configure() {
  79         # XXX: Conformance test suite (and clutter itself) does not work under Xvfb
  80         # (GLX error blabla)
  81         # XXX: coverage disabled for now
  82         # XXX: What about cex100/win32 backends?
  83         gnome2_src_configure \
  84                 --disable-maintainer-flags \
  85                 --disable-mir-backend \
  86                 --disable-gcov \
  87                 --disable-cex100-backend \
  88                 --disable-win32-backend \
  89                 --disable-tslib-input \
  90                 $(use_enable aqua quartz-backend) \
  91                 $(usex debug --enable-debug=yes --enable-debug=minimum) \
  92                 $(use_enable doc docs) \
  93                 $(use_enable egl egl-backend) \
  94                 $(use_enable egl evdev-input) \
  95                 $(use_enable gtk gdk-backend) \
  96                 $(use_enable introspection) \
  97                 $(use_enable test gdk-pixbuf) \
  98                 $(use_enable wayland wayland-backend) \
  99                 $(use_enable wayland wayland-compositor) \
 100                 $(use_enable X xinput) \
 101                 $(use_enable X x11-backend)
 102 }
 103
 104 src_test() {
 105         virtx emake check -C tests/conform
 106 }