media-libs/chromaprint/chromaprint-1.3.1.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6 inherit cmake-multilib
   7
   8 DESCRIPTION="A client-side library that implements a custom algorithm for extracting fingerprints"
   9 HOMEPAGE="http://acoustid.org/chromaprint"
  10 SRC_URI="https://bitbucket.org/acoustid/${PN}/downloads/${P}.tar.gz"
  11
  12 LICENSE="LGPL-2.1"
  13 SLOT="0/1"
  14 KEYWORDS="~alpha ~amd64 ~ppc ~ppc64 ~x86 ~amd64-fbsd"
  15 IUSE="libav test tools"
  16
  17 # note: use ffmpeg or libav instead of fftw because it's recommended and required for tools
  18 RDEPEND="
  19         libav? ( >=media-video/libav-11:0=[${MULTILIB_USEDEP}] )
  20         !libav? ( >=media-video/ffmpeg-2.6:0=[${MULTILIB_USEDEP}] )
  21 "
  22 DEPEND="${RDEPEND}
  23         test? (
  24                 dev-cpp/gtest[${MULTILIB_USEDEP}]
  25                 dev-libs/boost[${MULTILIB_USEDEP}]
  26         )"
  27
  28 DOCS="NEWS.txt README.md"
  29
  30 PATCHES=( "${FILESDIR}"/${PN}-1.1-gtest.patch )
  31
  32 multilib_src_configure() {
  33         local mycmakeargs=(
  34                 "-DBUILD_EXAMPLES=$(multilib_native_usex tools ON OFF)"
  35                 "-DBUILD_TESTS=$(usex test ON OFF)"
  36                 -DWITH_AVFFT=ON
  37                 )
  38         cmake-utils_src_configure
  39 }
  40
  41 multilib_src_test() {
  42         emake check
  43 }