media-libs/bio2jack/bio2jack-0.9-r2.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit autotools
   7
   8 DESCRIPTION="A library for porting blocked I/O OSS/ALSA audio applications to JACK"
   9 HOMEPAGE="http://bio2jack.sourceforge.net/"
  10 SRC_URI="mirror://sourceforge/bio2jack/${P}.tar.gz"
  11
  12 LICENSE="GPL-2"
  13 SLOT="0"
  14 KEYWORDS="alpha amd64 ~arm hppa ~ia64 ppc ppc64 ~sh sparc x86 ~amd64-linux ~x86-linux ~ppc-macos"
  15 IUSE="static-libs"
  16
  17 BDEPEND="
  18         virtual/pkgconfig
  19 "
  20 DEPEND="
  21         media-libs/libsamplerate
  22         virtual/jack"
  23 RDEPEND="${DEPEND}"
  24
  25 S=${WORKDIR}/${PN}
  26
  27 src_prepare() {
  28         default
  29
  30         # upstream does not provide a real release, it releases a tarball
  31         # with a _prebuilt_ copy of bio2jack. Drop all of the built stuff
  32         # and recreate autotools from scratch, then build.
  33         rm -r *.o *.la *.lo .libs .deps Makefile config.{log,status} stamp-h1 || die
  34
  35         eautoreconf
  36 }
  37
  38 src_configure() {
  39         econf \
  40                 --enable-shared \
  41                 $(use_enable static-libs static)
  42 }
  43
  44 src_install() {
  45         default
  46         dobin bio2jack-config
  47         rm -f "${ED}"/usr/lib*/lib*.la || die
  48 }