media-libs/babl/babl-0.1.62.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 if [[ ${PV} == *9999* ]]; then
   7         inherit autotools git-r3
   8         EGIT_REPO_URI="https://gitlab.gnome.org/GNOME/babl.git"
   9         SRC_URI=""
  10 else
  11         SRC_URI="http://ftp.gimp.org/pub/${PN}/${PV:0:3}/${P}.tar.bz2"
  12         KEYWORDS="alpha amd64 arm arm64 hppa ia64 ~mips ppc ppc64 ~sparc x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~x64-solaris ~x86-solaris"
  13 fi
  14
  15 DESCRIPTION="A dynamic, any to any, pixel format conversion library"
  16 HOMEPAGE="http://www.gegl.org/babl/"
  17
  18 LICENSE="LGPL-3"
  19 SLOT="0"
  20 IUSE="altivec cpu_flags_x86_sse cpu_flags_x86_sse2 cpu_flags_x86_sse3 cpu_flags_x86_sse4_1 cpu_flags_x86_mmx cpu_flags_x86_f16c"
  21
  22 RDEPEND=""
  23 DEPEND="${RDEPEND}
  24         >=sys-devel/libtool-2.2
  25         virtual/pkgconfig
  26 "
  27
  28 src_prepare() {
  29         default
  30         [[ ${PV} == *9999* ]] && eautoreconf
  31 }
  32
  33 src_configure() {
  34         # Automagic rsvg support is just for website generation we do not call,
  35         #     so we don't need to fix it
  36         # w3m is used for dist target thus no issue for us that it is automagically
  37         #     detected
  38         econf \
  39                 --disable-docs \
  40                 --disable-static \
  41                 --disable-maintainer-mode \
  42                 $(use_enable altivec) \
  43                 $(use_enable cpu_flags_x86_f16c f16c) \
  44                 $(use_enable cpu_flags_x86_mmx mmx) \
  45                 $(use_enable cpu_flags_x86_sse sse) \
  46                 $(use_enable cpu_flags_x86_sse2 sse2) \
  47                 $(use_enable cpu_flags_x86_sse3 sse3) \
  48                 $(use_enable cpu_flags_x86_sse4_1 sse4_1)
  49 }
  50
  51 src_install() {
  52         default
  53         find "${D}" -name '*.la' -type f -delete || die
  54 }