media-gfx/zbar/zbar-0.10_p20121015-r1.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=5
   5
   6 PYTHON_COMPAT=( python2_7 )
   7
   8 inherit autotools eutils flag-o-matic java-pkg-opt-2 multilib python-single-r1
   9
  10 DESCRIPTION="Library and tools for reading barcodes from images or video"
  11 HOMEPAGE="http://zbar.sourceforge.net/"
  12 SRC_URI="https://dev.gentoo.org/~xmw/zbar-0.10_p20121015.zip"
  13
  14 LICENSE="LGPL-2.1"
  15 SLOT="0"
  16 KEYWORDS="~amd64 ~arm ~x86"
  17 IUSE="gtk imagemagick java jpeg python qt4 static-libs +threads v4l X xv"
  18
  19 CDEPEND="gtk? ( dev-libs/glib:2 x11-libs/gtk+:2 )
  20         imagemagick? ( virtual/imagemagick-tools )
  21         jpeg? ( virtual/jpeg:0 )
  22         python? ( ${PYTHON_DEPS}
  23                 gtk? ( >=dev-python/pygtk-2[${PYTHON_USEDEP}] ) )
  24         qt4? ( dev-qt/qtcore:4 dev-qt/qtgui:4 )
  25         X? ( x11-libs/libXext
  26                 xv? ( x11-libs/libXv ) )"
  27 REPEND="${CDEPEND}
  28         java? ( >=virtual/jre-1.4 ) "
  29 DEPEND="${CDEPEND}
  30         java? ( >=virtual/jdk-1.4 )
  31         sys-devel/gettext
  32         virtual/pkgconfig"
  33
  34 REQUIRED_USE="${PYTHON_REQUIRED_USE}"
  35
  36 pkg_setup() {
  37         use python && python-single-r1_pkg_setup
  38         java-pkg-opt-2_pkg_setup
  39 }
  40
  41 src_unpack() {
  42         #vcs-snapshot doesn't work on .zip
  43         default
  44         mv * ${P} || die
  45 }
  46
  47 src_prepare() {
  48         epatch "${FILESDIR}"/${PN}-0.10-errors.patch \
  49                 "${FILESDIR}"/${PN}-0.10-python-crash.patch \
  50                 "${FILESDIR}"/${PN}-0.10-v4l2-uvcvideo.patch
  51
  52         use python && python_fix_shebang examples/upcrpc.py test/*.py
  53         java-pkg-opt-2_src_prepare
  54
  55         sed -e '/AM_INIT_AUTOMAKE/s: -Werror : :' \
  56                 -e '/^AM_CFLAGS=/s: -Werror::' \
  57                 -i configure.ac || die
  58         sed "s|javadir = \$(pkgdatadir)|javadir = /usr/$(get_libdir)/zbar|" \
  59                 -i java/Makefile.am
  60         eautoreconf
  61 }
  62
  63 src_configure() {
  64         if use java; then
  65                 export JAVACFLAGS="$(java-pkg_javac-args)"
  66                 export JAVA_CFLAGS="$(java-pkg_get-jni-cflags)"
  67         fi
  68
  69         append-cppflags -DNDEBUG
  70         econf \
  71                 $(use_with java) \
  72                 $(use_with jpeg) \
  73                 $(use_with gtk) \
  74                 $(use_with imagemagick) \
  75                 $(use_with python) \
  76                 $(use_with qt4 qt) \
  77                 $(use_enable static-libs static) \
  78                 $(use_enable threads pthread) \
  79                 $(use_with X x) \
  80                 $(use_with xv xv) \
  81                 $(use_enable v4l video)
  82 }
  83
  84 src_install() {
  85         emake DESTDIR="${D}" install
  86         dodoc HACKING NEWS README TODO
  87         rm -r "${ED}"/usr/share/doc/${PN}
  88         prune_libtool_files --all
  89 }
  90
  91 pkg_preinst() {
  92         java-pkg-opt-2_pkg_preinst
  93 }