media-gfx/xv/xv-3.10a-r19.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit eutils flag-o-matic toolchain-funcs
   7
   8 JUMBOV=20070520
   9 DESCRIPTION="Interactive image manipulation program supporting a wide variety of formats"
  10 HOMEPAGE="http://www.trilon.com/xv/index.html http://www.sonic.net/~roelofs/greg_xv.html"
  11 SRC_URI="mirror://sourceforge/png-mng/${P}-jumbo-patches-${JUMBOV}.tar.gz
  12         ftp://ftp.cis.upenn.edu/pub/xv/${P}.tar.gz
  13         mirror://gentoo/${P}.png.bz2"
  14
  15 LICENSE="xv"
  16 SLOT="0"
  17 KEYWORDS="~alpha amd64 hppa ~ia64 ~mips ppc ppc64 sparc x86 ~amd64-linux ~x86-linux ~ppc-macos"
  18 IUSE="jpeg tiff png"
  19
  20 DEPEND="x11-libs/libXt
  21         jpeg? ( virtual/jpeg:0 )
  22         tiff? ( media-libs/tiff:0 )
  23         png? ( >=media-libs/libpng-1.2:0= sys-libs/zlib )"
  24 RDEPEND="${DEPEND}"
  25
  26 PATCHES=(
  27         "${WORKDIR}/${P}-jumbo-fix-enh-patch-${JUMBOV}.txt"
  28         "${FILESDIR}/${P}-osx-bsd-${JUMBOV}.patch"
  29         "${FILESDIR}/${P}-vdcomp-osx-${JUMBOV}.patch"
  30         "${FILESDIR}/${P}-disable-jp2k-${JUMBOV}.patch"
  31         "${FILESDIR}/${P}-fix-wait-${JUMBOV}.patch"
  32         "${FILESDIR}/${P}-add-ldflags-${JUMBOV}.patch"
  33         "${FILESDIR}/${P}-libpng15-r1.patch"
  34         "${FILESDIR}/${P}-wformat-security.patch"
  35 )
  36
  37 src_prepare() {
  38         default
  39
  40         append-cppflags -DUSE_GETCWD -DLINUX -DUSLEEP
  41         use jpeg && append-cppflags -DDOJPEG
  42         use png && append-cppflags -DDOPNG
  43         use tiff && append-cppflags -DDOTIFF -DUSE_TILED_TIFF_BOTLEFT_FIX
  44
  45         # Link with various image libraries depending on use flags
  46         IMAGE_LIBS=""
  47         use jpeg && IMAGE_LIBS="${IMAGE_LIBS} -ljpeg"
  48         use png && IMAGE_LIBS="${IMAGE_LIBS} -lz -lpng"
  49         use tiff && IMAGE_LIBS="${IMAGE_LIBS} -ltiff"
  50
  51         sed -i \
  52                 -e 's/\(^JPEG.*\)/#\1/g' \
  53                 -e 's/\(^PNG.*\)/#\1/g' \
  54                 -e 's/\(^TIFF.*\)/#\1/g' \
  55                 -e "s/\(^LIBS = .*\)/\1${IMAGE_LIBS}/g" Makefile || die
  56
  57         # /usr/bin/gzip => /bin/gzip
  58         sed -i -e 's#/usr\(/bin/gzip\)#'"${EPREFIX}"'\1#g' config.h || die
  59
  60         # Fix installation of ps docs
  61         sed -i -e 's#$(DESTDIR)$(LIBDIR)#$(LIBDIR)#g' Makefile || die
  62 }
  63
  64 src_compile() {
  65         emake \
  66                 CC="$(tc-getCC)" CCOPTS="${CPPFLAGS} ${CFLAGS}" LDFLAGS="${LDFLAGS}" \
  67                 PREFIX="${EPREFIX}"/usr \
  68                 DOCDIR="${EPREFIX}/usr/share/doc/${PF}" \
  69                 LIBDIR="${T}"
  70 }
  71
  72 src_install() {
  73         dodir /usr/bin
  74         dodir /usr/share/man/man1
  75
  76         emake \
  77                 DESTDIR="${D}" \
  78                 PREFIX="${EPREFIX}"/usr \
  79                 DOCDIR="${EPREFIX}/usr/share/doc/${PF}" \
  80                 LIBDIR="${T}" install
  81
  82         dodoc CHANGELOG BUGS IDEAS
  83         newicon "${WORKDIR}"/${P}.png ${PN}.png
  84         make_desktop_entry xv "" "" "Graphics;Viewer"
  85 }