media-gfx/ufraw/ufraw-0.21.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6 inherit autotools eutils fdo-mime gnome2-utils toolchain-funcs
   7
   8 DESCRIPTION="RAW Image format viewer and GIMP plugin"
   9 HOMEPAGE="http://ufraw.sourceforge.net/"
  10 SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
  11
  12 LICENSE="GPL-2"
  13 SLOT="0"
  14 KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-freebsd ~amd64-linux ~x86-linux ~x64-solaris ~x86-solaris"
  15 IUSE="contrast fits gimp gnome gtk openmp timezone"
  16
  17 REQUIRED_USE="gimp? ( gtk )"
  18
  19 RDEPEND="
  20         dev-libs/glib:2=
  21         >=media-gfx/exiv2-0.11:0=
  22         media-libs/lcms:2=
  23         >=media-libs/lensfun-0.2.5:=
  24         media-libs/libpng:0=
  25         media-libs/tiff:0=
  26         virtual/jpeg:0=
  27         fits? ( sci-libs/cfitsio:0= )
  28         gnome? ( >=gnome-base/gconf-2 )
  29         gtk? ( >=x11-libs/gtk+-2.6:2
  30                 >=media-gfx/gtkimageview-1.5 )
  31         gimp? ( >=media-gfx/gimp-2 )
  32 "
  33 DEPEND="${RDEPEND}
  34         virtual/pkgconfig"
  35
  36 src_prepare() {
  37         epatch "${FILESDIR}"/${PN}-0.17-cfitsio-automagic.patch
  38         eautoreconf
  39 }
  40
  41 src_configure() {
  42         econf \
  43                 $(use_enable contrast) \
  44                 $(use_with fits cfitsio) \
  45                 $(use_with gimp) \
  46                 $(use_enable gnome mime) \
  47                 $(use_with gtk) \
  48                 $(use_enable openmp) \
  49                 $(use_enable timezone dst-correction)
  50 }
  51
  52 src_compile() {
  53         emake AR="$(tc-getAR)"
  54 }
  55
  56 src_install() {
  57         emake DESTDIR="${D}" schemasdir=/etc/gconf/schemas install
  58         dodoc README TODO
  59 }
  60
  61 pkg_preinst() {
  62         if use gnome; then
  63                 gnome2_gconf_savelist
  64         fi
  65 }
  66
  67 pkg_postinst() {
  68         if use gnome; then
  69                 fdo-mime_mime_database_update
  70                 fdo-mime_desktop_database_update
  71                 gnome2_gconf_install
  72         fi
  73 }
  74
  75 pkg_postrm() {
  76         if use gnome; then
  77                 fdo-mime_desktop_database_update
  78                 fdo-mime_mime_database_update
  79         fi
  80 }