media-gfx/qiv/qiv-2.3.2.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit desktop toolchain-funcs vcs-snapshot xdg
   7
   8 DESCRIPTION="Quick Image Viewer"
   9 HOMEPAGE="http://spiegl.de/qiv/ https://bitbucket.org/ciberandy/qiv"
  10 SRC_URI="https://bitbucket.org/ciberandy/qiv/get/v${PV}.tar.gz -> ${P}.tar.gz"
  11
  12 LICENSE="GPL-2"
  13 SLOT="0"
  14 KEYWORDS="~amd64 ~mips ~x86"
  15 IUSE="exif lcms magic"
  16
  17 RDEPEND="
  18         media-libs/imlib2[X]
  19         >=x11-libs/gtk+-2.12:2
  20         exif? ( media-libs/libexif )
  21         lcms? (
  22                 media-libs/lcms:2
  23                 media-libs/tiff:0
  24                 virtual/jpeg:0
  25         )
  26         magic? ( sys-apps/file )"
  27 DEPEND="${RDEPEND}
  28         virtual/pkgconfig"
  29
  30 PATCHES=( "${FILESDIR}"/${P}-optional-tiff.patch )
  31
  32 src_prepare() {
  33         default
  34
  35         sed -i \
  36                 -e 's:$(CC) $(CFLAGS):$(CC) $(LDFLAGS) $(CFLAGS):' \
  37                 Makefile || die
  38
  39         if ! use exif ; then
  40                 sed -i 's/^EXIF =/#\0/' Makefile || die
  41         fi
  42
  43         if ! use lcms ; then
  44                 sed -i 's/^LCMS =/#\0/' Makefile || die
  45         fi
  46
  47         if ! use magic ; then
  48                 sed -i 's/^MAGIC =/#\0/' Makefile || die
  49         fi
  50 }
  51
  52 src_compile() {
  53         emake CC="$(tc-getCC)" CFLAGS="${CFLAGS}"
  54 }
  55
  56 src_install() {
  57         dobin qiv
  58         doman qiv.1
  59         dodoc Changelog contrib/qiv-command.example README README.TODO
  60
  61         domenu qiv.desktop
  62         doicon qiv.png
  63 }