media-gfx/pstoedit/pstoedit-3.70-r1.ebuild

   1 # Copyright 1999-2016 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=6
   6
   7 inherit autotools
   8
   9 DESCRIPTION="Translate PostScript and PDF graphics into other vector formats"
  10 HOMEPAGE="https://sourceforge.net/projects/pstoedit/"
  11 SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
  12
  13 LICENSE="GPL-2"
  14 SLOT="0"
  15 KEYWORDS="alpha amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 sparc x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux"
  16 IUSE="emf flash imagemagick plotutils pptx static-libs"
  17
  18 RDEPEND="
  19         >=media-libs/gd-2.0.35-r1:=
  20         >=app-text/ghostscript-gpl-8.71-r1
  21         emf? ( >=media-libs/libemf-1.0.3 )
  22         flash? ( >=media-libs/ming-0.4.3 )
  23         imagemagick? ( >=media-gfx/imagemagick-6.6.1.2[cxx] )
  24         plotutils? ( media-libs/plotutils )
  25         pptx? ( dev-libs/libzip )
  26 "
  27 DEPEND="${RDEPEND}
  28         virtual/pkgconfig
  29 "
  30
  31 PATCHES=(
  32         "${FILESDIR}"/${PN}-3.60-libdl.patch
  33         "${FILESDIR}"/${PN}-3.70-pkgconfig.patch
  34 )
  35
  36 src_prepare() {
  37         default
  38
  39         sed -i \
  40                 -e '/CXXFLAGS="-g"/d' \
  41                 -e 's:-pedantic::' \
  42                 configure.ac || die
  43
  44         eautoreconf
  45 }
  46
  47 src_configure() {
  48         econf \
  49                 $(use_enable static-libs static) \
  50                 $(use_with emf) \
  51                 $(use_with imagemagick magick) \
  52                 $(use_with plotutils libplot) \
  53                 $(use_with flash swf) \
  54                 $(use_with pptx)
  55 }
  56
  57 src_install() {
  58         default
  59         doman doc/pstoedit.1
  60         dodoc doc/*.txt
  61         docinto html
  62         dodoc doc/*.htm
  63
  64         find "${ED}" -name '*.la' -delete
  65 }