media-gfx/pstoedit/pstoedit-3.70-r1.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6
   7 inherit autotools eutils
   8
   9 DESCRIPTION="Translate PostScript and PDF graphics into other vector formats"
  10 HOMEPAGE="http://sourceforge.net/projects/pstoedit/"
  11 SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
  12
  13 LICENSE="GPL-2"
  14 SLOT="0"
  15 KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux"
  16 IUSE="emf flash imagemagick plotutils pptx static-libs"
  17
  18 RDEPEND="
  19         >=media-libs/gd-2.0.35-r1:=
  20         >=app-text/ghostscript-gpl-8.71-r1
  21         emf? ( >=media-libs/libemf-1.0.3 )
  22         flash? ( >=media-libs/ming-0.4.3 )
  23         imagemagick? ( >=media-gfx/imagemagick-6.6.1.2[cxx] )
  24         plotutils? ( media-libs/plotutils )
  25         pptx? ( dev-libs/libzip )
  26 "
  27 DEPEND="${RDEPEND}
  28         virtual/pkgconfig
  29 "
  30
  31 src_prepare() {
  32         sed -i \
  33                 -e '/CXXFLAGS="-g"/d' \
  34                 -e 's:-pedantic::' \
  35                 configure.ac || die
  36
  37         epatch "${FILESDIR}"/${PN}-3.60-libdl.patch
  38         epatch "${FILESDIR}"/${PN}-3.70-pkgconfig.patch
  39
  40         eautoreconf
  41 }
  42
  43 src_configure() {
  44         econf \
  45                 $(use_enable static-libs static) \
  46                 $(use_with emf) \
  47                 $(use_with imagemagick magick) \
  48                 $(use_with plotutils libplot) \
  49                 $(use_with flash swf) \
  50                 $(use_with pptx)
  51 }
  52
  53 src_install() {
  54         default
  55         doman doc/pstoedit.1
  56         dodoc doc/*.txt
  57         dohtml doc/*.htm
  58
  59         find "${ED}" -name '*.la' -delete
  60 }